browserpass PKGBUILD hack

PKGBUILD

# Maintainer: emersion <contact emersion.fr>
pkgbase=browserpass
pkgname=('browserpass-host' 'browserpass-chrome' 'browserpass-chromium' 'browserpass-firefox')
pkgver=2.0.18
pkgrel=2
pkgdesc="Chrome & Firefox browser extension for pass, a UNIX password manager"
arch=('i686' 'x86_64')
url="https://github.com/dannyvankooten/browserpass"
license=('MIT')
depends=('pass')
makedepends=('go')
source=(
	"$pkgbase-$pkgver.tar.gz::https://github.com/dannyvankooten/browserpass/releases/download/$pkgver/browserpass-src.tar.gz"
	"$pkgbase-$pkgver.tar.gz.sig::https://github.com/dannyvankooten/browserpass/releases/download/$pkgver/browserpass-src.tar.gz.sig"
)
sha256sums=('1749dd2fde594894b7700a464d5a686663087b26d788d28909aab6801a1ceb52'
            'SKIP')
validpgpkeys=('EB4F9E5A60D32232BB52150C12C87A28FEAC6B20')


prepare() {
	_host_file="/usr/bin/browserpass"
	cd "$srcdir/$pkgbase"
	sed -i -e "s|%%replace%%|$_host_file|" chrome-host.json
	sed -i -e "s|%%replace%%|$_host_file|" firefox-host.json
}

build() {
	_GOPATH="$(pwd)/.go"

	_go_pkgname="github.com/dannyvankooten/browserpass"
	_go_pkgpath="$_GOPATH/src/$_go_pkgname"
	mkdir -p "$(dirname $_go_pkgpath)"
	ln -sf "$srcdir/$pkgbase" "$_go_pkgpath"

	cd "$srcdir/$pkgbase"
	rm -f browserpass # FIXME
	GOPATH=$_GOPATH make browserpass
}

package_browserpass-host() {
	pkgdesc+=" - host app"

	cd "$srcdir/$pkgbase"
	install -Dm755 browserpass "$pkgdir/usr/bin/browserpass"
	install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}

_app_name="com.dannyvankooten.browserpass"

package_browserpass-chrome() {
	_chromeroot='etc/opt/chrome'
	pkgdesc+=" - chrome host app config"
	optdepends+=('chrome')

	cd "$srcdir/$pkgbase"
	install -Dm644 chrome-host.json "$pkgdir/$_chromeroot/native-messaging-hosts/$_app_name.json"
	install -Dm644 chrome-policy.json "$pkgdir/$_chromeroot/policies/managed/$_app_name.json"
	install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}

package_browserpass-chromium() {
	_chromiumroot='etc/chromium'
	pkgdesc+=" - chromium host app config"
	optdepends+=('chromium')

	cd "$srcdir/$pkgbase"
	install -Dm644 chrome-host.json "$pkgdir/$_chromiumroot/native-messaging-hosts/$_app_name.json"
	install -Dm644 chrome-policy.json "$pkgdir/$_chromiumroot/policies/managed/$_app_name.json"
	install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}

package_browserpass-firefox() {
	_firefoxroot='usr/lib/firefox'
	pkgdesc+=" - firefox host app config"
	optdepends+=('firefox')

	cd "$srcdir/$pkgbase"
	install -Dm644 firefox-host.json "$pkgdir/usr/lib/mozilla/native-messaging-hosts/$_app_name.json"
	install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}