Seven languages in seven weeks :day 3 io

list.io

squareBrackets := method(
  r := List clone;
  call message arguments foreach(arg,
    r append(arg)
  )
)


languages := [
"Io",
"Ruby",
"Java"
];

languages println();

list_dirty.io

squareBrackets := method(
  call message arguments
)


languages := [
"Io",
"Ruby",
"Java"
];

languages println();

xmlbuilder.io

Builder := Object clone

Builder indentLevel := 0

Builder forward := method(

  writeln(indentBy(indentLevel), "<", call message name, ">");
  indentLevel = indentLevel + 1;

  call message arguments foreach(
	arg,

  	content := self doMessage(arg);
    if(content type == "Sequence", writeln(indentBy(indentLevel), content))
  )

  indentLevel = indentLevel -1;
  writeln(indentBy(indentLevel), "</", call message name, ">");

  )
Builder indentBy := method(indent,
    "   " repeated(indent)
 )

Builder  ul(
	li("Io"), 
	li("Lua"), 
	li("JavaScript"))

xmlbuilder_with_attributes

OperatorTable addAssignOperator(":" , "atPutAttribute")

Map atPutAttribute := method(
    self atPut(call evalArgAt(0) asMutable removePrefix("\"") removeSuffix("\""), call evalArgAt(1))
)

curlyBrackets := method(
    map1 := Map clone
    call message arguments foreach(arg,
        map1 doMessage(arg)
    )
)





Builder := Object clone

Builder indentLevel := 0

Builder forward := method(
  args := call message arguments

  write(indentBy(indentLevel), "<", call message name);

  if (args first name == "curlyBrackets", write(doMessage(args first) map(attr,val,
         " " .. attr .. "=" .. "\"" .. val .. "\""
      ) join);
       args = args rest);
  writeln(">");
  indentLevel = indentLevel + 1;

  args foreach(
	arg,
  	content := self doMessage(arg);
    if(content type == "Sequence", writeln(indentBy(indentLevel), content));

  )

  indentLevel = indentLevel -1;
  writeln(indentBy(indentLevel), "</", call message name, ">");

  )
Builder indentBy := method(indent,
    "   " repeated(indent)
 )

script := "Builder  ul({\"class\" : \"navigation\"}, li(\"Io\"), li({\"class\":\"selected\"}, a({\"title\":\"JavaScript\",\"href\":\"http://www.denoo.info\"},\"bla\")))"
doString(script)