Promisified version of smtp-server

smtp-server-as-promised.ls

require! {
  'promise-once-events'
  'smtp-server'
}

const SERVER_PORT = 25

module.exports = class smtp-server-as-promised extends promise-once-events
  (@options = {}) ->

    {
      @backlog = 0
      @host
      @port = SERVER_PORT
    } = @options

    @address = {}

    options = {} <<< @options <<< do
      onConnect: (session, ack) ~>
        @emit 'connect', session, ack
      onMailFrom: (address, session, ack) ~>
        @emit 'mailFrom', address, session, ack
      onRcptTo: (address, session, ack) ~>
        @emit 'rcptTo', address, session, ack
      onData: (stream, session, ack) ~>
        @emit 'data', stream, session, ack
      onClose: (session) ~>
        @emit 'close', session

    @server = new smtp-server.SMTPServer options

  listen: (done) ->
    new Promise (resolve, reject) ~>
      rejector = (err) ~>
        reject err
      @server.once 'error', rejector
      @server.listen @port, @host, @backlog, ~>
        @server.removeListener 'error', rejector
        @address = @server.server.address!
        resolve!