Migrate from Evernote to "Notes"

01_README.md

I got sick of Evernote's feature creep, and decided to give "Notes.app" a try. This was partially because you can have some folders backed by Exchange, others backed by iCloud, and others backed by IMAP, so you have better control over your data.

To use this AppleScript, change the first two lines. Create the target folder in Notes.app before you run the script. (I put my work notes into my employer's Exchange server and my personal notes into iCloud for now.)

I could not find a way to set the creation date programmatically, and that's why I put it as the first line of each new note, so the information would not be lost. (I may update the script to do something similar with tags.)

EvernoteMigration.scpt

set sourceNotebook to "Work"
set targetFolder to "Work Evernote Import"

tell application "Evernote"
	tell notebook named sourceNotebook
		copy notes to myOldNotes
	end tell
end tell

tell application "Notes"
	tell folder named targetFolder
		repeat with myOldNote in items of myOldNotes
			using terms from application "Evernote"
				set thisName to title of myOldNote
				set thisDate to creation date of myOldNote as string
				set thisBody to HTML content of myOldNote
			end using terms from
			set myNewNote to make new note
			set name of myNewNote to thisName
			set body of myNewNote to thisDate & "<br/><br/>" & thisBody
		end repeat
	end tell
end tell