Clojure macro to define strict keyword argument functions

defnk.clj

(defmacro defnk
  [name & fdecl]
  (let [doc-string? (when (string? (first fdecl))
                      (first fdecl))
        fdecl (if (string? (first fdecl))
                (next fdecl)
                fdecl)
        attr-map? (when (map? (first fdecl))
                    (first fdecl))
        fdecl (if (map? (first fdecl))
                (next fdecl)
                fdecl)
        params (first fdecl)
        m (gensym)
        params* [{:keys params :as m}]
        fdecl (next fdecl)
        prepost-map? (if (map? (first fdecl))
                       (first fdecl)
                       {})
        fdecl (if (map? (first fdecl))
                (next fdecl)
                fdecl)
        body fdecl]
    `(defn ~name
       ~@(if doc-string? [doc-string?] [])
       ~@(if attr-map? [attr-map?] [])
       ~params*
       ~(merge-with (comp vec concat)
                    prepost-map?
                    {:pre [`(every? some? ~params)
                           `(= ~(count params) (count ~m))]})
       ~@body)))

Wrote this as a medium reply: https://medium.com/@didibus/what-about-3e278cada532