ktlint with Gradle Kotlin DSL

ktlint.gradle.kts

val ktlint by configurations.creating

dependencies {
    ktlint(Libraries.ktlint)
}

tasks.register<JavaExec>("ktlint") {
    group = "verification"
    description = "Check Kotlin code style."
    classpath = ktlint
    main = "com.github.shyiko.ktlint.Main"
    args("--android", "src/**/*.kt")
}

tasks.named("check") {
    dependsOn(ktlint)
}

tasks.register<JavaExec>("ktlintFormat") {
    group = "formatting"
    description = "Fix Kotlin code style deviations."
    classpath = ktlint
    main = "com.github.shyiko.ktlint.Main"
    args("--android", "-F", "src/**/*.kt")
}

I cannot import Libraries.

Either declare using buildSrc, or just replace Libraries.ktlint with "com.github.shyiko:ktlint:0.29.0".

object Versions {
    const val ktlint = "0.29.0"
}

object Libraries {
    const val ktlint = "com.github.shyiko:ktlint:${Versions.ktlint}"
}

If the dependence of tasks do not work, try this:

tasks.named("check") {
  dependsOn(tasks.named("ktlint"))
}

awesome, thank you