A JBoss7 standalone instance "Windows service" handler. Files for this bug report: https://sourceforge.net/projects/yajsw/forums/forum/810311/topic/8275368

standalone.conf.bat

@ECHO off
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
::                                                                          ::
::  JBoss 6EAP/7CE Bootstrap Script Configuration                           ::
::      Called by standalone.bat .                                          ::
::                                                                          ::
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

:: Uncomment the following line to disable manipulation of JAVA_OPTS (JVM parameters)
:: SET PRESERVE_JAVA_OPTS=true

IF NOT DEFINED JAVA_OPTS (
  ECHO "JAVA_OPTS already SET in environment. Overriding default settings with values: %JAVA_OPTS%"
  GOTO :JAVA_OPTS_SET
)

::
:: Specify the JBoss Profiler configuration file to load.
::
:: Default is to not load a JBoss Profiler configuration file.
::
:: SET "PROFILER=%JBOSS_HOME%\bin\jboss-profiler.properties"

::
:: Specify the exact Java VM executable to use - only used if JAVA_HOME is
:: not set. Default is "java".
::
SET "JAVA=%JAVA_HOME%\bin\java"

::
:: Specify options to pass to the Java VM. Note, there are some additional
:: options that are always passed by run.bat.
::

:: JVM memory allocation pool parameters - modify as appropriate.
::SET "JAVA_OPTS=-Xms1303M -Xmx1303M -XX:MaxPermSize=256M"

:: Reduce the RMI GCs to once per hour for Sun JVMs.
::SET "JAVA_OPTS=%JAVA_OPTS% -Dsun.rmi.dgc.client.gcInterval=3600000 -Dsun.rmi.dgc.server.gcInterval=3600000"

:: Warn when resolving remote XML DTDs or schemas.
SET "JAVA_OPTS=%JAVA_OPTS% -Dorg.jboss.resolver.warning=true -Djava.net.preferIPv4Stack=true"

:: Make Byteman classes visible in all module loaders
:: This is necessary to inject Byteman rules into AS7 deployments
SET "JAVA_OPTS=%JAVA_OPTS% -Djboss.modules.system.pkgs=org.jboss.byteman"

:: SET the default configuration file to use if -c or --server-config are not used
SET "JAVA_OPTS=%JAVA_OPTS% -Djboss.server.default.config=standalone.xml"

:: Sample JPDA settings for remote socket debugging
:: SET "JAVA_OPTS=%JAVA_OPTS% -Xrunjdwp:transport=dt_socket,address=8787,server=y,suspend=n"

:: Sample JPDA settings for shared memory debugging
:: SET "JAVA_OPTS=%JAVA_OPTS% -Xrunjdwp:transport=dt_shmem,address=jboss,server=y,suspend=n"

:: Use JBoss Modules lockless mode
:: SET "JAVA_OPTS=%JAVA_OPTS% -Djboss.modules.lockless=true"

:JAVA_OPTS_SET
ECHO End of %~nx0 script.

STANDALONE_SERVICE.bat

@ECHO off
::-------------------------------------------------------------------
::  This is a script that handles the YAJSW Windows service wrapper
::    for Java.  Without args, this script will prompt.
::  Place this script in the JBoss bin directory and run it.
::  This script calls the Jboss standalone.conf.bat file to load some properties.
::  This script requires all 3 files contained in this Gist
::  This script forces you to run 32bit JBoss with 32bit cmd.exe shell
::     unless you run in a 64bit shell.
::  This script should work with JBoss 6EAP or Jboss 7CE
::  Use one copy of this script for each instance directory and set the
::     DEFAULT_INSTANCE variable correctly in this file.
::    Author: Jon Austen, Portland, OR
::    Date:  May 2013
::-------------------------------------------------------------------
SETLOCAL ENABLEDELAYEDEXPANSION ENABLEEXTENSIONS
CLS

::-------------------------------------------------------------------
::  JAVA_HOME override   
::    Uncomment the next line to override JAVA_HOME on your system  
::-------------------------------------------------------------------
SET JAVA_HOME=C:\AeroFS\Java64\jdk1.7.0_17_x64\jre

::-------------------------------------------------------------------
::  Set TITLE, JBOSS_HOME, and DIRNAME variables
::-------------------------------------------------------------------
SET JBOSS_HOME=%~dp0
SET "JBOSS_HOME=%JBOSS_HOME:bin\=%"
IF %JBOSS_HOME:~-1%==\ SET "JBOSS_HOME=%JBOSS_HOME:~0,-1%"
SET "THISFILE=%~nx0"
SET TITLE=Starting %THISFILE%

:: a hack to let all subprocesses of YAJSW resolve java.home
SET jboss.home=%JBOSS_HOME%

::-------------------------------------------------------------------
::  Configuration: 
::     before running you need to configure these
::-------------------------------------------------------------------
IF "%1"=="" (
  SET DELAY=20
) ELSE (
  SET DELAY=5
)
SET DEBUG_LEVEL=DEBUG
SET DEFAULT_INSTANCE=ports-01
:: comment next line if you want script to prompt user for service startup TYPE
SET STARTUP_TYPE=auto
SET VER=

::-------------------------------------------------------------------
::  Parse script args
::-------------------------------------------------------------------
IF "%3%"=="" (
  ECHO There are not 3 args.
  IF "%2"=="" (
    ECHO There are not 2 args.
    IF "%1"=="" (
    ECHO There is not even 1 script arg.
	  SET INSTANCE=%DEFAULT_INSTANCE%
	  SET TYPE=%STARTUP_TYPE%
	  SET ACTION=
	  GOTO :SETTYPE
	) ELSE (
	  ECHO There is 1 arg.
	  SET ACTION=%1
	  SET INSTANCE=%DEFAULT_INSTANCE%
	  SET TYPE=%STARTUP_TYPE%
	  GOTO :SETTYPE
	)
  ) ELSE (
    ECHO There are 2 args.
	  SET ACTION=%1
	  ECHO Setting INSTANCE name to second script argument: %2
	  SET INSTANCE=%2
	  SET TYPE=%STARTUP_TYPE%
    GOTO :SETTYPE
  )
) ELSE (
  ECHO There are 3 args.
  IF NOT "%ACTION%"=="" (
    ECHO Setting ACTION to execute: %1
  )
  SET ACTION=%1
  ECHO Setting INSTANCE name of service: %2
  SET INSTANCE=%2
  ECHO Setting TYPE of service startup: %3
  SET TYPE=%3
)
:SETTYPE
:: next, if STARTUP_TYPE is set to blank, prompt for it
IF "%TYPE%"=="" (
  SET TYPE=
  ECHO.&ECHO.
  ECHO --------------------------
  ECHO    Service can be registered to start in different ways:
  ECHO      boot,system,auto,demand,disabled, or delayed-auto
  ECHO --------------------------
  SET /P "TYPE=Choose a service TYPE type: "
) ELSE (
  SET TYPE=%TYPE%
)
CALL :verifytype
ECHO.
ECHO Parsed args: 1:%ACTION% 2:%INSTANCE% 3:%TYPE%
:BEGIN

::-------------------------------------------------------------------
::  Main script
::-------------------------------------------------------------------
CALL :mainheader
CALL :checks
CALL :wrappersetup
GOTO :MENU
:MENURESET
SET ACTION=
:MENU
SET TITLETEXT=%THISFILE% running JBOSS in ^"%JBOSS_HOME%\%INSTANCE%\^"
TITLE %TITLETEXT%
ECHO.
ECHO -----------------------------
ECHO    Options MENU:
ECHO ----------------------------- &ECHO.
ECHO [install]  Install service
ECHO   [start]  Start service
ECHO    [stop]  Stop service
ECHO  [remove]  Remove or uninstall service
ECHO [console]  Run service as console
ECHO  [query]  Query service status
ECHO   [usage]  Display usage help
ECHO       [X]  Exit script
ECHO.
ECHO -----------------------------
ECHO.
IF "%ACTION%"=="" SET /P "ACTION=Choose an action type in this MENU to execute: "
ECHO.
IF "%ACTION%"=="X" GOTO :EOF
IF "%ACTION%"=="x" GOTO :EOF
IF "%ACTION%"=="usage" (
  CALL :usage
  PAUSE
  IF "%1"=="" GOTO :MENURESET
)
IF "%ACTION%"=="install" (
  CALL :startheader
  CALL :addservice
  IF "%1"=="" GOTO :MENURESET
)
IF "%ACTION%"=="start" (
  SC.exe start %SERVICE_NAME%
  CALL :servicestatus
  IF "%1"=="" GOTO :MENURESET
)
IF "%ACTION%"=="stop" (
  SC.exe stop %SERVICE_NAME%
  CALL :servicestatus
  IF "%1"=="" GOTO :MENURESET
)
IF "%ACTION%"=="remove" (
  SC.exe delete %SERVICE_NAME%
  IF "%1"=="" GOTO :MENURESET
)
IF "%ACTION%"=="console" (
  DEL /Q "%JBOSS_HOME%\wrapper\log\*%INSTANCE%.log*"
  SET TITLETEXT=JBOSS wrapper console in ^"%JBOSS_HOME%\%INSTANCE%^"
  TITLE !TITLETEXT!
  CALL :startheader
  CALL :consoleservice
  IF "%1"=="" GOTO :MENURESET
)
IF "%ACTION%"=="query" (
  CALL :startheader
  CALL :queryservice
  CALL :displayports
  IF "%1"=="" GOTO :MENURESET
)

GOTO :END
::-------------------------------------------------------------------
::  Functions
::-------------------------------------------------------------------
:addservice
ECHO Function: addservice
ECHO ***********************
ECHO Using wrapper to install service : service-name=%SERVICE_NAME%, startup-type=%TYPE%
ECHO "%JAVA_HOME%\bin\java.exe" %WRAPPER_ARGS% -jar %JBOSS_HOME%\bin\wrapper\wrapper.jar -i %WRAPPER_CONFIG_FILE%
CALL "%JAVA_HOME%\bin\java.exe" %WRAPPER_ARGS% -jar %JBOSS_HOME%\bin\wrapper\wrapper.jar -i %WRAPPER_CONFIG_FILE%
ECHO.
ECHO ***********************
SC.exe config %SERVICE_NAME% start= %TYPE%
ECHO Installing service ^"%SERVICE_NAME%^" is finished.
ECHO ***********************
ECHO.
EXIT /B 0

:checks
:: TODO: check not JBoss7
IF NOT EXIST wrapper\lib (
  ECHO.
  ECHO The YAJSW distributions 'lib' directory is needed in a directory called .\wrapper
  ECHO that is relative to this script and the run.bat .
  ECHO Under .\wrapper you also need the wrapper.jar and wrapper.jboss.conf .
  ECHO Download distro from http://sourceforge.net/projects/yajsw/ .
  C:
  START "%ProgramFiles%\Internet Explorer\iexplore.exe" http://sourceforge.net/projects/yajsw
  ECHO.
  CALL :waitseconds 10
  GOTO :END
)
IF NOT EXIST standalone.bat (
  ECHO This file must be run from the JBoss bin directory.
  ECHO Could not find standalone.bat script.
  GOTO :END
)
IF NOT DEFINED JAVA_HOME (
  ECHO JAVA_HOME must be defined as an environment variable.
  GOTO :END
) ELSE (
  SET "PATH=%JAVA_HOME%\bin;%PATH%"
)
IF NOT EXIST "%JAVA_HOME%" (
  ECHO JAVA_HOME must be defined to an actual location.
  ECHO Also, make sure you used the override in this script correctly.
  GOTO :END
)
::-------------------------------------------------------------------
::  Detect Java version
::-------------------------------------------------------------------
ECHO Detecting Java version...
FOR /f "tokens=3" %%g IN ('java.exe -version 2^>^&1 ^| FINDSTR /I "version"') DO (
    SET JAVAVER=%%g
)
SET JAVAVER=%JAVAVER:"=%
ECHO Java Version: %JAVAVER%
FOR /F "delims=. tokens=1-3" %%v IN ("!JAVAVER!") DO (
	SET TMPVAR=%%x&SET TMPVAR=!TMPVAR:~-2!
    SET JAVABUILD=!TMPVAR!
    SET JAVAVER=%%v.%%w
	ECHO Major: %%v , Minor: %%w, Build: !JAVABUILD!
)
SET TMPVAR=
IF "%JAVAVER%"=="1.5" (
  ECHO JBoss 7 requires using JRE 1.6+
  GOTO :END
)
IF "%JAVAVER%"=="1.4" (
  ECHO JBoss 7 requires using JRE 1.6+
  GOTO :END
)
IF "%JAVAVER%"=="1.3" (
  ECHO JBoss 7 requires using JRE 1.6+
  GOTO :END
)

IF "%INSTANCE%"=="" (
  ECHO Instance name must be defined in this script file for
  ECHO the named instance in directory: %JBOSS_HOME%\ .
  GOTO :END
)
IF NOT EXIST wrapper\wrapperApp.jar (
  ECHO You need to copy the wrapperApp.jar into place at bin\wrapper\wrapperApp.jar
  GOTO :END
)
IF NOT EXIST wrapper\wrapper.jar (
  ECHO You need to copy the wrapperApp.jar into place at bin\wrapper\wrapper.jar
  GOTO :END
)
IF EXIST wrapper\YAJSW.sample.wrapper.conf (
  IF NOT EXIST wrapper\%INSTANCE%.wrapper.conf (
    COPY wrapper\YAJSW.sample.wrapper.conf wrapper\%INSTANCE%.wrapper.conf
  )
) ELSE (
  ECHO Missing file YAJSW.sample.wrapper.conf from .\wrapper directory in %JBOSS_HOME%\bin .
  GOTO :END
)
::-------------------------------------------------------------------
::  Detect windows shell architecture
::-------------------------------------------------------------------
SET ProgramFiles(x86) | FIND "not defined"
IF ERRORLEVEL 0 (
  SET CMD_ARCH=64
) ELSE (
  SET CMD_ARCH=32
)
ECHO Command shell architecture is %CMD_ARCH%

::-------------------------------------------------------------------
::  Detect Java JRE architecture and SET JAVA_ARCH
::-------------------------------------------------------------------
ECHO Checking that JRE bit architecture matches cmd.exe bit architecture...
"%JAVA_HOME%\bin\java.exe" -version 2>&1 | findstr "64-Bit"
IF %ERRORLEVEL% == 0 (
  SET JAVA_ARCH=64
) ELSE (
  SET JAVA_ARCH=32
)
ECHO Java architecture is %JAVA_ARCH%-bit.
SET MS=512M
IF "%JAVA_ARCH%"=="64" (
  IF "%CMD_ARCH%"=="64" (
    SET MM=2048M
    SET MPS=312M
    ECHO Max memory set to !MM! ^(with !MPS! permsize^) in %JAVA_ARCH%-bit JVM in a %CMD_ARCH%-bit shell.
  ) ELSE (
    ECHO A 64-bit JVM cannot run in a 32-bit shell.
  )
) ELSE (
  IF "%CMD_ARCH%"=="64" (
    SET MM=1500M
    SET MPS=312M
    ECHO Max memory set to !MM! ^(with !MPS! permsize^) in %JAVA_ARCH%-bit JVM in a %CMD_ARCH%-bit shell.
  ) ELSE (
    SET MM=1500M
    SET MPS=312M
    ECHO Max memory set to !MM! ^(with !MPS! permsize^) in %JAVA_ARCH%-bit JVM in a %CMD_ARCH%-bit shell.
  )
)
ECHO.
IF NOT EXIST wrapper\tmp (
  MKDIR wrapper\tmp
)
IF NOT EXIST wrapper\log (
  MKDIR wrapper\log
)
IF NOT EXIST "%JBOSS_HOME%\%INSTANCE%" (
  ::RD.exe /S /Q "%JBOSS_HOME%\standalone\tmp"
  XCOPY.exe "%JBOSS_HOME%\standalone" "%JBOSS_HOME%\%INSTANCE%" /Y /E /F /I
)
ECHO.
EXIT /B 0

:consoleservice
ECHO Function: consoleservice
ECHO Run wrapper in console for service ^"%SERVICE_NAME%^"
ECHO ***********************
ECHO Using wrapper to run in console : service-name=%SERVICE_NAME%, startup-type=%TYPE%
ECHO Running service in console...
ECHO "%JAVA_HOME%\bin\java.exe" %WRAPPER_ARGS% -jar %JBOSS_HOME%\bin\wrapper\wrapper.jar -c %WRAPPER_CONFIG_FILE%
CALL "%JAVA_HOME%\bin\java.exe" %WRAPPER_ARGS% -jar %JBOSS_HOME%\bin\wrapper\wrapper.jar -c %WRAPPER_CONFIG_FILE%
ECHO.
ECHO ***********************
EXIT /B 0

:mainheader
TITLE %TITLE_TEXT%
ECHO ------------------------------------
EXIT /B 0

:queryservice
ECHO Function: queryservice
ECHO Run wrapper to query ^"%SERVICE_NAME%^"
ECHO ***********************
ECHO "%JAVA_HOME%\bin\java.exe" %WRAPPER_ARGS% -jar %JBOSS_HOME%\bin\wrapper\wrapper.jar -q %WRAPPER_CONFIG_FILE%
CALL "%JAVA_HOME%\bin\java.exe" %WRAPPER_ARGS% -jar %JBOSS_HOME%\bin\wrapper\wrapper.jar -q %WRAPPER_CONFIG_FILE%
ECHO.
ECHO ***********************
EXIT /B 0

:servicestatus
ECHO Checking status of service...
CALL :waitseconds 2
sc.exe query %SERVICE_NAME% | find "STATE">query.tmp
ECHO.
FOR /F "tokens=1,4 delims=, " %%I IN ( query.tmp ) DO (
  ECHO Status of ^"%SERVICE_NAME%^" : %%I - %%J
  IF "%%J"=="START_PENDING" (
    ECHO Service is pending a start.
    SET "PENDING=true"
    SET "RUNNING=unknown"
  ) ELSE IF "%%J"=="STOP_PENDING" (
    ECHO Service is pending a stop.
    SET "PENDING=true"
    SET "RUNNING=unknown"
  ) ELSE IF "%%J"=="STOPPED" (
    ECHO Service is stopped.
    SET "PENDING=false"
    SET "RUNNING=false"
  ) ELSE IF "%%J"=="RUNNING" (
    ECHO Service is running.
    SET "PENDING=false"
    SET "RUNNING=true"
  ) 
)
DEL /Q query.tmp
IF "%PENDING%"=="true" GOTO :servicestatus
EXIT /B 0

:settitle
SET TITLETEXT=JBoss ^"!SERVICE_NAME!^" Service Controller
TITLE %TITLETEXT%
EXIT /B 0

:startheader
:: Generated by: http://patorjk.com/software/taag/#p=display&f=Star%20Wars&t=JBoss
ECHO        __  .______     ______        _______.     _______.
ECHO       ^|  ^| ^|   _  \   /  __  \      /       ^|    /       ^|
ECHO       ^|  ^| ^|  ^|_)  ^| ^|  ^|  ^|  ^|    ^|   (----`   ^|   (----`
ECHO .--.  ^|  ^| ^|   _  ^<  ^|  ^|  ^|  ^|     \   \        \   \    
ECHO ^|  `--'  ^| ^|  ^|_)  ^| ^|  `--'  ^| .----)   ^|   .----)   ^|   
ECHO  \______/  ^|______/   \______/  ^|_______/    ^|_______/    
ECHO. 
ECHO.
ECHO Script environment:
ECHO     JAVA_HOME=%JAVA_HOME%
ECHO     JBOSS_HOME=%JBOSS_HOME%
ECHO     WRAPPER_ARGS=%WRAPPER_ARGS%
ECHO     SERVICE_NAME=%SERVICE_NAME%
ECHO     ACTION=%ACTION%
ECHO     WRAPPER_CONFIG_FILE: %WRAPPER_CONFIG_FILE%
ECHO     TYPE=%TYPE%
ECHO.
ECHO.
EXIT /B 0

:usage
ECHO.
ECHO -----------------------------
ECHO   Usage:
ECHO -----------------------------
ECHO MENU will not be displayed if any arg is passed : &ECHO.
ECHO      %~n0%~x0 start JBOSS_%INSTANCE%
ECHO      %~n0%~x0 stop
ECHO      %~n0%~x0 add JBOSS_%INSTANCE%
ECHO      %~n0%~x0 add
ECHO      %~n0%~x0 console JBOSS_%INSTANCE%
ECHO      %~n0%~x0 query JBOSS_%INSTANCE%
ECHO.
ECHO -----------------------------
ECHO.
EXIT /B 0

:verifytype
SET FAIL=true
IF "%TYPE%"=="boot" SET FAIL=false
IF "%TYPE%"=="system" SET FAIL=false
IF "%TYPE%"=="auto" SET FAIL=false
IF "%TYPE%"=="demand" SET FAIL=false
IF "%TYPE%"=="disabled" SET FAIL=false
IF "%TYPE%"=="delayed-auto" SET FAIL=false
IF "%FAIL%"=="true" (
  SET TYPE=
  ECHO Invalid TYPE option.  Try again.
  ECHO.
  GOTO :SETTYPE
)
ECHO Startup TYPE is: %TYPE%
EXIT /B 0

:waitseconds timeArg
SET /A VAL=%1
ECHO Pausing for %VAL% seconds.
SET /A DUR=%VAL%*2
PING.exe -n %DUR% -w 1000 127.0.0.1>nul
EXIT /B 0

:wrappersetup
SET SERVICE_NAME=JBOSS_%INSTANCE%
SET "WRAPPER_CONFIG_FILE=%JBOSS_HOME%\bin\wrapper\%INSTANCE%.wrapper.conf"
SET "WRAPPER_ARGS=%WRAPPER_ARGS% -Dservice.name=%SERVICE_NAME% -Dinstance.name=%INSTANCE%"
SET "WRAPPER_ARGS=%WRAPPER_ARGS% -Djava.home="%JAVA_HOME%" -Djboss.ms=%MS% -Djboss.mm=%MM%"
SET "WRAPPER_ARGS=%WRAPPER_ARGS% -Djboss.mps=%MPS%"
SET "WRAPPER_ARGS=%WRAPPER_ARGS% -Ddebug.level=%DEBUG_LEVEL%"
::  Change back-slashes to forward-slashes before passing options to the wrapper
SET "WRAPPER_ARGS=%WRAPPER_ARGS:\=/%"
EXIT /B 0

::-------------------------------------------------------------------
::  End script
::-------------------------------------------------------------------
:END
ECHO.
ECHO Service script is finished and will close automatically in %DELAY% seconds.
FOR /l %%a IN (%DELAY%,-1,1) DO (TITLE JBoss %APPDIR% -- Closing in %%as&PING.exe -n 2 -w 1000 127.0.0.1>nul)

YAJSW.sample.wrapper.conf

## wrapper.conf

## parsed args from script
wrapper.java.home=${java_home}
wrapper.jboss.dir=${jboss_home}
wrapper.debug.level=${debug.level}
wrapper.jboss.instance=${instance.name}
wrapper.app.servicename=${service.name}
wrapper.minheap=${jboss.ms}
wrapper.maxheap=${jboss.mm}
wrapper.permsize=${jboss.mps}

## wrapper configuration
wrapper.java.command=${wrapper.java.home}\\bin\\java.exe
wrapper.ntservice.java.command=${wrapper.java.command}
wrapper.console.loglevel=${wrapper.debug.level}
wrapper.debug=true
wrapper.tray=false

wrapper.working.dir=${wrapper.jboss.dir}

wrapper.java.classpath.1=${wrapper.jboss.dir}/jboss-modules.jar
wrapper.java.app.jar=${wrapper.jboss.dir}/jboss-modules.jar

wrapper.app.parameter.1=-mp
wrapper.app.parameter.2=${wrapper.jboss.dir}/modules
wrapper.app.parameter.3=-jaxpmodule
wrapper.app.parameter.4=javax.xml.jaxp-provider
wrapper.app.parameter.5=org.jboss.as.standalone

wrapper.java.additional.1=-XX:+UseCompressedOops
wrapper.java.additional.2=-XX:+TieredCompilation
wrapper.java.additional.3=-Dprogram.name=standalone.bat
wrapper.java.additional.4=-Xms${wrapper.minheap}
wrapper.java.additional.5=-Xmx${wrapper.maxheap}
wrapper.java.additional.6=-XX:MaxPermSize=${wrapper.permsize}
wrapper.java.additional.7=-Dsun.rmi.dgc.client.gcInterval=3600000
wrapper.java.additional.8=-Dsun.rmi.dgc.server.gcInterval=3600000
wrapper.java.additional.9=-Dorg.jboss.resolver.warning=true
wrapper.java.additional.10=-Djboss.server.base.dir=${wrapper.jboss.dir}/${wrapper.jboss.instance}
wrapper.java.additional.11=-Dorg.jboss.as.logging.per-deployment=false
wrapper.java.additional.12=-Djboss.server.default.config=standalone.xml
wrapper.java.additional.13=-Djava.net.preferIPv4Stack=true
wrapper.java.additional.14=-Djboss.modules.system.pkgs=org.jboss.byteman
wrapper.java.additional.15=-Dlogging.configuration=file:${wrapper.jboss.dir}/${wrapper.jboss.instance}/configuration/logging.properties
wrapper.java.additional.16=-Dorg.jboss.boot.log.file=${wrapper.jboss.dir}/${wrapper.jboss.instance}/log/boot.log
wrapper.java.additional.17=-Djavax.management.builder.initial=org.jboss.system.server.jmx.MBeanServerBuilderImpl
wrapper.java.additional.18=-Djboss.platform.mbeanserver
wrapper.java.additional.19=-Djboss.home.dir=${wrapper.jboss.dir}
#wrapper.java.additional.20=-Dwrapper.jboss.dir=${jboss.home}

# wrapper log location
wrapper.logfile=${wrapper.jboss.dir}/bin/wrapper/log/${wrapper.app.servicename}.log
wrapper.logfile.loglevel=DEBUG

wrapper.console.title=JBOSS Service YAJSW Console
wrapper.ntservice.name=${wrapper.app.servicename}
wrapper.ntservice.displayname=${wrapper.app.servicename}
wrapper.ntservice.description=JBoss at ${wrapper.jboss.dir}/${wrapper.jboss.instance}
wrapper.ntservice.autoreport.startup=true
#wrapper.ntservice.autoreport.startup=false
#wrapper.app.account=
#wrapper.ntservice.account=
#wrapper.ntservice.password=