Split a large XML file into several smaller XML files

README.md

How to run

saxon -s:in.xml -xsl:split.xsl name=Products size=1200

split.xsl

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

    <xsl:output method="xml" indent="yes"/>

    <xsl:param name="size">1200</xsl:param>
    <xsl:param name="name">out</xsl:param>

    <xsl:variable name="timestamp">
        <xsl:value-of select="format-dateTime(current-dateTime(), '[Y0001]-[M01]-[D01]-[H01]-[m01]-[s01]')"/>
    </xsl:variable>

    <xsl:template match="/">
        <xsl:variable name="root" select="name(/*)" />

        <xsl:for-each-group select="/*/*" group-adjacent="floor((position() - 1) div $size)">
            <xsl:variable name="key">
                <xsl:value-of select="format-number(current-grouping-key(), '00000')" />
            </xsl:variable>
            
            <xsl:result-document href="{$name}-{$timestamp}-{$key}.xml">
                <xsl:element name="{$root}">
                    <xsl:copy-of select="current-group()"/>
                </xsl:element>
            </xsl:result-document>
        </xsl:for-each-group>
    </xsl:template>
</xsl:stylesheet>