Debugging method calls using TracingInterceptor

TracingInterceptorSample.groovy

/* 
 * Nice way to debug method calls by intercepting all method invocations 
 * on a GroovyObject using TracingInterceptor.
 */

class MyClass {
    String name
    
    def reverse() { name.reverse() } 
    def upperCase() { name.toUpperCase() }
    def buggyMethod() { throw new Exception() } 
}

def proxy = ProxyMetaClass.getInstance(MyClass.class)
proxy.interceptor = new TracingInterceptor()

println '** With constructor call interceptions ** '
// with constructor call interception
proxy.use {
    def myObj = new MyClass( name: 'John Miller' )
    assert myObj.reverse() == 'relliM nhoJ'
    myObj.name = 'walter white'
    assert myObj.upperCase() == 'WALTER WHITE'
}

println '\n** Avoid intercepting constructor calls ** '

// Avoid intercepting constructor calls
def myObj = new MyClass( name: 'John Miller' )
proxy.use( myObj ) {
    assert myObj.reverse() == 'relliM nhoJ'
    myObj.name = 'walter white'
    assert myObj.upperCase() == 'WALTER WHITE'
    
    // Only prints before interception
    // After interceptor not reached
    try { myObj.buggyMethod() } catch ( e ) { println 'Eating Exception' }
}