Arch Linux sdrpp-git (AUR)

PKGBUILD

# Maintainer: Alexandre Rouma <whatsthetgeek@gmail.com>
# Maintainer: éclairevoyant

# Contributor: Marin Atanasov Nikolov <dnaeon@gmail.com>

_pkgname=sdrpp
pkgname="${_pkgname}-git"
pkgver=1.0.4.r479.3a06612
pkgrel=1
epoch=
pkgdesc='Cross-Platform SDR Software'
arch=('x86_64')
url='https://www.sdrpp.org/'
license=('GPL')
depends=(glfw fftw glew libvolk rtaudio)
_plugindeps=(airspy airspyhf-git bladerf hackrf libad9361 libiio libsdrplay limesuite rtl-sdr soapysdr)
makedepends=(cmake git "${_plugindeps[@]}")
optdepends=("${_plugindeps[@]}")
provides=("${_pkgname}")
conflicts=("${_pkgname}")
source=("${_pkgname}::git+https://github.com/AlexandreRouma/SDRPlusPlus")
b2sums=('SKIP')

pkgver() {
  cd "${_pkgname}"
  git describe --long --tags --exclude nightly | sed 's/\([^-]*-\)g/r\1/;s/-/./g'
}

build() {
  cmake -B build \
        -S "${_pkgname}" \
        -DOPT_BUILD_BLADERF_SOURCE=ON \
        -DOPT_BUILD_LIMESDR_SOURCE=ON \
        -DOPT_BUILD_SDRPLAY_SOURCE=ON \
        -DOPT_BUILD_NEW_PORTAUDIO_SINK=ON \
        -DOPT_BUILD_M17_DECODER=ON

  make -C build VERBOSE=1
}

package() {
  make -C build DESTDIR="${pkgdir}/" install
}