Arch Linux gpredict-git (AUR)

PKGBUILD

# Maintainer: not_anonymous <nmlibertarian@gmail.com>
# Contributor: Marin Atanasov Nikolov <dnaeon@gmail.com>
# Contributor: Andrey Semisokhin <customs.rnd@gmail.com>
# Original Submission: Bob Finch <w9ya@qrparci.net>

_pkgname=gpredict
pkgname="${_pkgname}-git"
pkgver=2.3.r115.0f3beb6
pkgrel=1
pkgdesc='Gpredict satellite tracking application'
arch=('i686' 'x86_64')
url='http://gpredict.oz9aec.net/'
license=('GPL')
depends=('curl' 'goocanvas')
makedepends=('git' 'autoconf' 'automake' 'intltool')
optdepends=('hamlib: Ham radio equipment control libraries')
provides=("${_pkgname}")
conflicts=("${_pkgname}")
source=('git+https://github.com/csete/gpredict')
sha256sums=('SKIP')

pkgver() {
  cd "${_pkgname}"
  git describe --long --tags | sed 's/^v//;s/\([^-]*-\)g/r\1/;s/-/./g;s/\.rc./rc/g'
}

build() {
  cd "${_pkgname}"
  ./autogen.sh
  ./configure --prefix=/usr
  make
}

check() {
  cd "${_pkgname}"
  make -k check
}

package() {
  cd "${_pkgname}"
  make DESTDIR="${pkgdir}/" install
}