Async IO seems to be a bit racy

async.pm

my $server = IO::Socket::Async.listen('localhost', 5000).tap(-> $conn {
    my $message = '';
    $conn.chars_supply.tap(-> $chars {
        $message ~= $chars;
        if $message.index("\n") -> $end {
            $conn.send($message.substr(0, $end) ~ ' back').then({ $conn.close });
        }
    }, quit => { say $_; });
});

sub client(Str $message) {
    my $p = Promise.new;
    my $v = $p.vow;

    my $client = IO::Socket::Async.connect('localhost', 5000).then(-> $sr {
       if $sr.status == Kept {
          my $socket = $sr.result;
          
          my @chunks;
          $socket.chars_supply.tap(-> $chars { @chunks.push($chars) },
                done => {
                    $socket.close();
                    $v.keep(@chunks.join());
                },
                quit => { $v.break($_); });

          $socket.send($message ~ "\n").then(-> $wr {
              if $wr.status == Broken {
                  $v.break($wr.cause);
                  $socket.close();
              }
          });
        }
        else {
            $v.break($sr.cause);
        }
    });
    $p
}

say 'Starting ...';
for 1..10 {
	say await client("hello {$_}");
}