Runs windows update standalone files which have been downloaded by http://www.windowsupdatesdownloader.com/

auto_install_windows_updates.au3

#include <File.au3>
#RequireAdmin

Local $location = "C:\Users\dorukcan\Documents\Windows Updates Downloader\Non-Security Updates\"
Local $aFileList = _FileListToArray($location, "*")

For $i = 1 To $aFileList[0]
   ;open file
   ShellExecute($location & $aFileList[$i])
   ConsoleWrite($i & " " & $aFileList[$i] & @CRLF)

   ;click ok to install
   Local $okWin = WinWait("[TITLE:Windows Update Standalone Installer; CLASS:#32770]")
   WinActivate($okWin)
   Local $text = ControlGetText($okWin, "", "Static1")
   ControlClick($okWin, "", "Button1")
   If StringInStr($text, "already") Then
	  ProcessWaitClose("wusa.exe")
	  ContinueLoop
   EndIf

   ;wait for installation done and close the window
   Local $insWin = WinWait("Download and Install Updates", "Installation complete")
   WinActivate($insWin)
   ControlClick($insWin, "", "Button4")

   ;be sure about the previous process has been closed
   ProcessWaitClose("wusa.exe")
Next