kube-sort.libsonnet

local safeGet = function(name) function(o, default={}) if std.objectHas(o, name) then o[name] else default;
local metadata = safeGet("metadata");
local name = safeGet("name");
local namespace = safeGet("namespace");
local kind = safeGet("kind");
local kindPriority = std.foldl(function(o, k) o { [k]: std.length(o) }, [
    "Namespace",
    "ResourceQuota",
    "LimitRange",
    "PodSecurityPolicy",
    "PodDisruptionBudget",
    "Secret",
    "ConfigMap",
    "StorageClass",
    "PersistentVolume",
    "PersistentVolumeClaim",
    "ServiceAccount",
    "CustomResourceDefinition",
    "ClusterRole",
    "ClusterRoleBinding",
    "Role",
    "RoleBinding",
    "Service",
    "DaemonSet",
    "Pod",
    "ReplicationController",
    "ReplicaSet",
    "Deployment",
    "StatefulSet",
    "Job",
    "CronJob",
    "Ingress",
    "APIService",
], {});
local priority = function(kind) if std.objectHas(kindPriority, kind) then kindPriority[kind] else std.length(kindPriority);
local keyF = function(o) std.format("%02d/%s/%s/%s", [priority(kind(o, "")), namespace(metadata(o), ""), kind(o, ""), name(metadata(o), "")]);

keyF