PKGBUILD

# Maintainer: Kyle Brady  <kyle at spark-gap dot com>
# Contributor: Patrick Hof <courts@offensivethinking.org>
# Contributor: Michael Fellinger <mf@rubyists.com>
# Contributor: Daichi Shinozaki <dsdseg@gmail.com>

pkgname=haxe
pkgver=2.08
pkgrel=4
pkgdesc="An open source programming language."
arch=('i686' 'x86_64')
url="http://haxe.org"
license=('GPL')
depends=('neko')
makedepends=('neko' 'ocaml' 'cvs' 'subversion' 'zlib')
options=('!strip' 'emptydirs')
install=${pkgname}.install
source=('http://haxe.org/file/install.ml'
        'haxe.csh'
        'haxe.sh'
	'haxeserver')
md5sums=('50eb4333f70496970d1ee0f4c61a83bb'
         '5e0e656293e92a6437d76f2f406438b5'
         '79cbf6ebdb3d56e980d1a17fa9cb3b2d'
         'e72130ef5479e0285d400b6331892008')
	 
build() {
  cd "$srcdir"
  ocaml install.ml
  export HAXE_LIBRARY_PATH=${srcdir}/haxe/std:.
  bin/haxe haxe/std/tools/haxedoc/haxedoc.hxml
  bin/haxe haxe/std/tools/haxelib/haxelib.hxml
  cd haxe/doc
  ../../bin/haxe all.hxml
  if [ -e flash8.xml -a -e flash9.xml -a -e neko.xml -a -e js.xml -a -e php.xml -a -e cpp.xml ] 
  then
    msg "generating api docs..."
    ../../haxedoc \
      "flash8.xml;flash" "neko.xml;neko" "js.xml;js" \
      "flash9.xml;flash9;flash" "php.xml;php" "cpp.xml;cpp" \
    && echo " done."
  fi
}

package() {
  install -d ${pkgdir}/usr/{bin,share/doc/haxe,lib/haxe/lib} ${pkgdir}/opt/haxe
  cd "$srcdir"
  cp -r haxe/std ${pkgdir}/opt/haxe/
  cp bin/* ${pkgdir}/usr/bin/
  install haxedoc haxelib ${pkgdir}/usr/bin/
  find "$pkgdir" -name ".svn" -print0 | xargs -0 rm -rf
  install "${srcdir}/haxeserver" "${pkgdir}/usr/bin/"
  install -D -T "${srcdir}/haxe.sh" "${pkgdir}/etc/profile.d/haxe.sh"
  install -D -T "${srcdir}/haxe.csh" "${pkgdir}/etc/profile.d/haxe.csh"
  cd haxe/doc
  cp -r content index.html ${pkgdir}/usr/share/doc/haxe
}

# vim:set ts=2 sw=2 et:

haxe v2.08-3 PKGBUILD for ArchLinux

haXe AUR - Package Details
https://aur.archlinux.org/packages.php?ID=16697