[Windows Batch] DDNS (MyDNSJP)にグローバルIPアドレスを通知する

update_ip_mydnsjp.bat

@ECHO OFF
rem --This Windows Batch file is tells DDNS (MyDNSJP) the global IP address

rem --Value
set ddnsid=userid
set ddnspass=password
set ddnsurl=https://www.mydns.jp/directip.html

set logfile=mydnsjp.log
set gipv4url=https://inet-ip.info/ip

rem --Main
echo. >> %logfile%
echo ----[%date% %time%]---- >> %logfile%

rem --Get Globle IP address info
curl %gipv4url% > gipv4.tmp

findstr "^[1-9]*\.[0-9]*\.[0-9]*\.[0-9]" gipv4.tmp > nul
if not %errorlevel%==0 (
    echo "(Error) Failed to get global IP address info" >> %logfile%
    del gipv4.tmp
    exit /b 1
)

rem --Put the IP address in a variable
set /p gipv4=<gipv4.tmp
del gipv4.tmp
echo. >> %logfile%

rem --Update IP address to DDNS
curl "%ddnsurl%?MID=%ddnsid%&PWD=%ddnspass%&IPV4ADDR=%gipv4%" >> ddns.tmp

rem --NOTE:May be necessary to change the conditional expression
findstr "Login.and.IP.address.notify.OK\." ddns.tmp > nul
if not %errorlevel%==0 (
    echo "(Error) Failed to upload global IP address to DDNS" >> %logfile%
    del ddns.tmp
    exit /b 2
)

echo ---Result LOG---- >> %logfile%
type ddns.tmp >> %logfile%
del ddns.tmp
echo. >> %logfile%
exit /b 0

• 新規作成
• Windows 10で実施
• DDNS通知後の条件式に変更があるかも