Last active
April 17, 2020 00:16
-
-
Save duhminick/966559bdfecb74df2ec5d1fd4c938ef2 to your computer and use it in GitHub Desktop.
This file contains bidirectional Unicode text that may be interpreted or compiled differently than what appears below. To review, open the file in an editor that reveals hidden Unicode characters.
Learn more about bidirectional Unicode characters
/* | |
* Project 'Stream Cheap' Mini Macro Keyboard | |
* @author David Madison | |
* @link partsnotincluded.com/electronics/diy-stream-deck-mini-macro-keyboard | |
* @license MIT - Copyright (c) 2018 David Madison | |
* | |
* Permission is hereby granted, free of charge, to any person obtaining a copy | |
* of this software and associated documentation files (the "Software"), to deal | |
* in the Software without restriction, including without limitation the rights | |
* to use, copy, modify, merge, publish, distribute, sublicense, and/or sell | |
* copies of the Software, and to permit persons to whom the Software is | |
* furnished to do so, subject to the following conditions: | |
* | |
* The above copyright notice and this permission notice shall be included in | |
* all copies or substantial portions of the Software. | |
* | |
* THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR | |
* IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY, | |
* FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE | |
* AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER | |
* LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, | |
* OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN | |
* THE SOFTWARE. | |
* | |
*/ | |
// --------------------------------- | |
// Key definitions | |
#define BUTTON_KEY1 KEY_F13 | |
#define BUTTON_KEY2 MEDIA_NEXT | |
#define BUTTON_KEY3 MEDIA_PLAY_PAUSE | |
#define BUTTON_KEY4 MEDIA_PREVIOUS | |
#define BUTTON_KEY5 KEY_F17 | |
#define BUTTON_KEY6 KEY_F18 | |
#define BUTTON_KEY7 KEY_F19 | |
#define BUTTON_KEY8 KEY_F20 | |
// Pin definitions | |
#define BUTTON_PIN1 2 | |
#define BUTTON_PIN2 3 | |
#define BUTTON_PIN3 4 | |
#define BUTTON_PIN4 5 | |
#define BUTTON_PIN5 6 | |
#define BUTTON_PIN6 7 | |
#define BUTTON_PIN7 8 | |
#define BUTTON_PIN8 9 | |
// Consumer definitions | |
#define BUTTON_CONSUMER1 false | |
#define BUTTON_CONSUMER2 true | |
#define BUTTON_CONSUMER3 true | |
#define BUTTON_CONSUMER4 true | |
#define BUTTON_CONSUMER5 false | |
#define BUTTON_CONSUMER6 false | |
#define BUTTON_CONSUMER7 false | |
#define BUTTON_CONSUMER8 false | |
// --------------------------------- | |
#include "HID-Project.h" | |
// Button helper class for handling press/release and debouncing | |
class button { | |
public: | |
const uint8_t key; | |
const uint8_t pin; | |
const boolean consumer; | |
button(uint8_t k, uint8_t p, boolean c) : key(k), pin(p), consumer(c){} | |
void press(boolean state){ | |
if(state == pressed || (millis() - lastPressed <= debounceTime)){ | |
return; // Nothing to see here, folks | |
} | |
lastPressed = millis(); | |
if (consumer) | |
state ? Consumer.press((ConsumerKeycode)key) : Consumer.release((ConsumerKeycode)key); | |
else | |
state ? Keyboard.press((KeyboardKeycode)key) : Keyboard.release((KeyboardKeycode)key); | |
pressed = state; | |
} | |
void update(){ | |
press(!digitalRead(pin)); | |
} | |
private: | |
const long debounceTime = 30; | |
unsigned long lastPressed; | |
boolean pressed = 0; | |
} ; | |
// Button objects, organized in array | |
button buttons[] = { | |
{BUTTON_KEY1, BUTTON_PIN1, BUTTON_CONSUMER1}, | |
{BUTTON_KEY2, BUTTON_PIN2, BUTTON_CONSUMER2}, | |
{BUTTON_KEY3, BUTTON_PIN3, BUTTON_CONSUMER3}, | |
{BUTTON_KEY4, BUTTON_PIN4, BUTTON_CONSUMER4}, | |
{BUTTON_KEY5, BUTTON_PIN5, BUTTON_CONSUMER5}, | |
{BUTTON_KEY6, BUTTON_PIN6, BUTTON_CONSUMER6}, | |
{BUTTON_KEY7, BUTTON_PIN7, BUTTON_CONSUMER7}, | |
{BUTTON_KEY8, BUTTON_PIN8, BUTTON_CONSUMER8}, | |
}; | |
const uint8_t NumButtons = sizeof(buttons) / sizeof(button); | |
const uint8_t ledPin = 17; | |
void setup() { | |
// Safety check. Ground pin #1 (RX) to cancel keyboard inputs. | |
pinMode(1, INPUT_PULLUP); | |
if(!digitalRead(1)){ | |
failsafe(); | |
} | |
// Set LEDs Off. Active low. | |
pinMode(ledPin, OUTPUT); | |
digitalWrite(ledPin, HIGH); | |
TXLED0; | |
for(int i = 0; i < NumButtons; i++){ | |
pinMode(buttons[i].pin, INPUT_PULLUP); | |
} | |
Keyboard.begin(); | |
Consumer.begin(); | |
} | |
void loop() { | |
for(int i = 0; i < NumButtons; i++){ | |
buttons[i].update(); | |
} | |
} | |
void failsafe(){ | |
for(;;){} // Just going to hang out here for awhile :D | |
} |
Sign up for free
to join this conversation on GitHub.
Already have an account?
Sign in to comment