Rust Nix Flake Setup

flake.nix

{
  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";
    flake-utils.url = "github:numtide/flake-utils";
    fenix = {
      url = "github:nix-community/fenix";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    naersk = {
      url = "github:nix-community/naersk";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs = { self, nixpkgs, flake-utils, fenix, naersk }:
    flake-utils.lib.eachDefaultSystem (system: let
      pkgs = nixpkgs.legacyPackages.${system};
      rust-toolchain = fenix.packages.${system}.toolchainOf {
        channel = "1.62.1";
        # sha256 = pkgs.lib.fakeSha256;
        sha256 = "sha256-Et8XFyXhlf5OyVqJkxrmkxv44NRN54uU2CLUTZKUjtM=";
      };
    in rec {
      # Build the crate and bin
      packages.default = (naersk.lib.${system}.override {
        inherit (rust-toolchain) cargo rustc;
      }).buildPackage { src = ./.; };

      # Run the bin
      apps.default = flake-utils.lib.mkApp {
        drv = packages.default;
        exePath = "/bin/main";
      };

      # For use with `nix develop`
      devShells.default = pkgs.mkShell {
        nativeBuildInputs = [
          (rust-toolchain.withComponents [
            "cargo"
            "clippy"
            "rustc"
            "rustfmt"
            "rust-src"
          ])
        ];
      };
    });
}