Gradle script to upload java components into Repository Manager

build.gradle

apply plugin: 'java'
apply plugin: 'maven-publish'
apply plugin: 'distribution'

archivesBaseName = 'my-component'
group = 'io.eddumelendez.gradle'
version = '1.0'
sourceCompatibility = 1.7

task sourcesJar(type: Jar) {
    baseName 'my-component'
    classifier 'sources'
    from sourceSets.main.allSource
}

task javadocJar(type: Jar, dependsOn: javadoc) {
    baseName 'my-component'
    classifier 'javadoc'
    from javadoc.destinationDir
}

artifacts {
    archives sourcesJar
    archives javadocJar
}

distributions {
    main {
        baseName = archivesBaseName

        contents {
            from { libsDir }
        }
    }

    docs {
        baseName = "$archivesBaseName-docs"

        contents {
            from(libsDir) {
                include sourcesJar.archiveName
                include javadocJar.archiveName
            }
        }
    }
}

ext {
    artifactoryBaseUrl = 'http://localhost:8081/artifactory'
    artifactorySnapshotRepoUrl = "$artifactoryBaseUrl/libs-snapshot-local"
    artifactoryReleaseRepoUrl = "$artifactoryBaseUrl/libs-release-local"
    artifactoryUsername = "admin"
    artifactoryPassword = "password"
}

publishing {
    publications {
        plugin(MavenPublication) {
            from components.java
            artifactId 'my-component'
            artifact sourcesJar
            artifact javadocJar
        }
    }

    repositories {
        mavenLocal()

        maven {
            name 'remoteArtifactory'
            url project.version.endsWith('-SNAPSHOT') ? artifactorySnapshotRepoUrl : artifactoryReleaseRepoUrl

            credentials {
                username = artifactoryUsername
                password = artifactoryPassword
            }
        }
    }
}

Why won't you use Artifactory Gradle Plugin? It takes care of everything.