the software for Glasgow, the Scottish Army Knife for electronics, packaged for Nix

default.nix

{ python3Packages, fetchgit, fetchFromGitHub, sdcc, makeWrapper, yosys, nextpnr, icestorm }:
let
    self = python3Packages // (with self; {
        fx2 = buildPythonPackage rec {
            pname = "fx2";
            version = "0.6";
            src = fetchPypi {
                inherit pname version;
                sha256 = "c2126cd9fff71e399d664ac0e40958d609e80209ac8950b4e2ca07d2e8fb06d9";
            };
            propagatedBuildInputs = [ libusb1 ];
        };
        migen = buildPythonPackage {
            pname = "migen";
            version = "2019-01-31";
            src = fetchFromGitHub {
                owner = "m-labs";
                repo = "migen";
                rev = "afe4405becdbc76539f0195c319367187012b05e";
                sha256 = "1f288a7ll1d1gjmml716wsjf1jyq9y903i2312bxb8pwrg7fwgvz";
            };
            propagatedBuildInputs = [ colorama sphinx sphinx_rtd_theme ];
        };
        glasgow = buildPythonPackage {
            pname = "glasgow";
            version = "2019-01-23";
            src = fetchgit {
                url = https://github.com/whitequark/Glasgow;
                rev = "c6ae4e6b5f361e99161e9931b8f1bc287c8afac1";
                sha256 = "1fl60z7hbg10ppwars4ria82fj1m6g7i73ypvpni5066yf11ja2n";
                fetchSubmodules = true;
            };
            preConfigure = "cd software";
            propagatedBuildInputs = [
                versioneer migen fx2 libusb1 pyvcd bitarray crcmod
                yosys nextpnr icestorm
            ];
            buildInputs = [ sdcc makeWrapper ];
            doCheck = false;
        };
    });
in self.glasgow