Python mark inside/outside quotes

gistfile1.el

(if (fboundp 'python-beginning-of-string)
    ;; python.el
    (defun er--python-string-start-pos ()
      "Returns character address of start of string, nil if not inside. "
      (let ((pt (point)))
        (save-excursion
          ;; python-beginning-of-string returns the current
          ;; position if point is not in a string, so we have
          ;; to check if point moved, and if not, we check if
          ;; we weren't already on the first quote of a string
          (python-beginning-of-string)
          (cond ((/= pt (point)) (point))
                ((looking-at "\"\\|'") (point))
                (t nil)))))
  ;; python-mode.el
  (defalias 'er--python-string-start-pos 'py-in-string-p))

(defun er/mark-inside-python-quotes ()
  "Mark the inside of the current string, not including the quotation marks."
  (interactive)
  (let ((beg (er--python-string-start-pos)))
    (when beg
      (goto-char beg)
      ;; Skipping quote characters one-by-one will do the wrong thing
      ;; if a triple-quoted string ends with an escaped quote, e.g.
      ;; """The last word is \"quoted.\""""
      (let ((q-skip (if (looking-at "\"\"\"\\|'''") 3 1)))
        (forward-sexp)
        (backward-char q-skip)
        (set-mark (point))
        (goto-char beg)
        (forward-char q-skip)))))

(defun er/mark-outside-python-quotes ()
  "Mark the current string, including the quotation marks."
  (interactive)
  (let ((beg (er--python-string-start-pos)))
    (when beg
      (goto-char beg)
      (set-mark (point))
      (forward-sexp)
      (exchange-point-and-mark))))