Genuary2023 24: Random flowers & polygons, neater parallax movement, cleaner code

Gen_20230124.pde

/*
   ____   __                 __       __  ___              _
  / __/__/ /_ _____ ________/ /__    /  |/  /__  _______ _(_)__
 / _// _  / // / _ `/ __/ _  / _ \  / /|_/ / _ \/ __/ _ `/ (_-<
/___/\_,_/\_,_/\_,_/_/  \_,_/\___/ /_/  /_/\___/_/  \_,_/_/___/
 
 Genuary 2023! 24
 * by Eduardo Morais 2023 - www.eduardomorais.pt
 */

// libs
// import processing.javafx.*;


// config
int   $appWinWidth   = 1024;
int   $appWinHeight  = 1024;
color $appWinBG      = #000000; // #110D92;
color $appDefStroke  = #FFFFFF;

int   $saveFrameNum  = 0; // 0 to deactivate
int   $saveFrameOffset  = 300; // wait before start recording


// constants
int MAXRAD = 128;
int MAXSTROKE = 8;
int MAXPETALS = 12;
int MAXSIDES = 16;
float MAXSPD = 4;

int FLOWER_NUM = 48;
int POLY_NUM = 128;

// globals
Flower[] flowers;
Poly[] polys;
int cellX, cellY, maxRad, minRad;


/*
  SETTINGS & SETUP
 */
void settings() {
  // brute MS Surface display density fix:   
  size($appWinWidth / displayDensity(), $appWinHeight / displayDensity());
  MAXRAD/=displayDensity();
  MAXSTROKE/=displayDensity();
}

color fgcolor(int hs, int he) { 
  colorMode(HSB, 360, 100, 100);
  return color(random(hs, he), random(50, 100), random(50, 100));
}

void setup() {
  colorMode(HSB, 360, 100, 100);
  $appWinBG =  color(random(150, 210), random(50, 100), 16);
  
  background($appWinBG);
  noFill();
  noCursor();
  frameRate(30);

  flowers = new Flower[FLOWER_NUM];
  polys = new Poly[POLY_NUM];

  colorMode(HSB, 360, 100, 100);

  for (int i=0; i<FLOWER_NUM; i++) {
    flowers[i] = new Flower(
      int(random(width,width*2)), int(random(0,height)),    // pos
      MAXRAD / 10, random(MAXRAD / 8,MAXRAD),                // radius
      int(random(2, random(MAXPETALS/2, MAXPETALS))),       // petals
      random(-PI, PI),                                      // st ang
      fgcolor(0, 120), int(random(2, MAXSTROKE))            // color, stroke
      );
  }

  for (int i=0; i<POLY_NUM; i++) {
    polys[i] = new Poly(
      int(random(width,width*2)), int(random(0,height)),    // pos
      MAXRAD / 8, random(MAXRAD / 8,MAXRAD),                        // radius
      int(random(3, random(MAXSIDES/2, MAXSIDES))),         // sides
      random(-PI, PI),                                      // st ang
      fgcolor(300, 360), int(random(2, MAXSTROKE))          // color, stroke
      );
  }

}


/*
 DRAW
 */
void draw() {
  windowBlur($appWinBG, 96);

  blendMode(BLEND);
  for (int i=0; i<polys.length; i++) {
    polys[i].draw(32);
  } 

  blendMode(SCREEN);
  for (int i=0; i<flowers.length; i++) {
    flowers[i].draw(16);
  } 



  if ($saveFrameNum > 0 && 
    frameCount > $saveFrameOffset && frameCount - $saveFrameOffset <= $saveFrameNum)
      saveFrame("frames/#####.tga");
    
}

/* polygons */

class Poly {
  PVector position;
  float minrad, maxrad, rad, rot, avel, xvel;
  int strokew, sides;
  color col;

  Poly(int x, int y, float mird, float mxrd, int p, float sr, color c, int sw) {
    position = new PVector(x, y);
    minrad = mird;
    maxrad = mxrd;
    rad = random(minrad, maxrad);
    rot = sr;
    xvel = map(rad, 0, MAXRAD, 1, MAXSPD);
    avel = xvel/30;
    avel = sr >=0 ? avel : 0-avel;
    sides = p;
    col = c;
    strokew = sw;
  }

  void draw(int opacity) {
    rot+=avel/10;
    position.x-=xvel;
    
    if (position.x < 0-maxrad*2) {
      position = new PVector(int(random(width,width*2)), int(random(0,height)));
      avel = 0 - avel;
      strokew = int(random(2, MAXSTROKE));
      sides = int(random(2, MAXSIDES));

      return;
    }

    stroke(col, opacity);
    strokeWeight(strokew);
    noFill();

    pushMatrix();
    translate(position.x, position.y);
    rotate(rot);
    
    polygon(0,0, rad, sides);
    
    popMatrix();

  }
}


/* our flower figure */

class Flower {
  PVector position;
  float minrad, maxrad, rot, avel, xvel;
  int strokew, petals;
  color col;

  Flower(int x, int y, float mird, float mxrd, int p, float sr, color c, int sw) {
    position = new PVector(x, y);
    minrad = mird;
    maxrad = mxrd;
    rot = sr;
    xvel = map(maxrad, 0, MAXRAD, 1, MAXSPD);
    avel = xvel/30;
    avel = sr >=0 ? avel : 0-avel;
    petals = p;
    col = c;
    strokew = sw;
  }

  void draw(int opacity) {
    rot+=avel/10;
    position.x-=xvel;
    
    if (position.x < 0-maxrad*2) {
      position = new PVector(int(random(width,width*2)), int(random(0,height)));
      avel = 0 - avel;
      strokew = int(random(2, MAXSTROKE));
      petals = int(random(2, MAXPETALS));

      return;
    }

    stroke(col, opacity);
    strokeWeight(strokew);
    noFill();

    pushMatrix();
    translate(position.x, position.y);
    rotate(rot);
    
    flower(0,0, minrad, maxrad, petals, 60);
 
    popMatrix();

  }
}

/* draw flower */

void flower(float x, float y, float minrad, float maxrad, int npetals, int detail) {
  if (detail < npetals*4) detail = npetals * 4;
  float ac = TAU / detail;
  PVector pos = new PVector(x,y);

  for (float angle = 0; angle < TAU; angle+=ac) {
    float radius = lerp(minrad, maxrad, abs(sin(angle*npetals)));
    PVector drawto = PVector.fromAngle(angle).setMag(radius);
    drawto = PVector.add(pos, drawto);

    line(x, y, drawto.x, drawto.y);
  }
}


/* from the Regular Polygon example */

void polygon(float x, float y, float radius, int npoints) {
  float angle = TWO_PI / npoints;
  beginShape();
  for (float a = 0; a < TWO_PI; a += angle) {
    float sx = x + cos(a) * radius;
    float sy = y + sin(a) * radius;
    vertex(sx, sy);
  }
  endShape(CLOSE);
}


/* Full window blur */
void windowBlur(color bg, int opacity) {
   blendMode(BLEND);
   noStroke();
   fill(bg, opacity);
   rectMode(CORNER);
   rect(0,0, width, height);
   noFill();
}