Genuary2023 23: Random flowers & polygons, movement with rotation and scale

Gen_20230123.pde

/*
   ____   __                 __       __  ___              _
  / __/__/ /_ _____ ________/ /__    /  |/  /__  _______ _(_)__
 / _// _  / // / _ `/ __/ _  / _ \  / /|_/ / _ \/ __/ _ `/ (_-<
/___/\_,_/\_,_/\_,_/_/  \_,_/\___/ /_/  /_/\___/_/  \_,_/_/___/
 
 Genuary 2023! 23
 * by Eduardo Morais 2023 - www.eduardomorais.pt
 */

// libs
// import processing.javafx.*;


// config
int   $appWinWidth   = 1024;
int   $appWinHeight  = 1024;
color $appWinBG      = #000000; // #110D92;
color $appDefStroke  = #FFFFFF;

int   $saveFrameNum  = 0; // 0 to deactivate
int   $saveFrameOffset  = 300; // wait before start recording


// constants
int MAXRAD = 192;
int ROTATIONS = 4;
int MAXSTROKE = 8;
int MAXPETALS = 10;
int MAXSIDES = 16;
float MAXSPD = 4;

int FLOWER_NUM = 32;
int POLY_NUM = 32;

// globals
Flower[] flowers;
Poly[] polys;
int cellX, cellY, maxRad, minRad;


/*
  SETTINGS & SETUP
 */
void settings() {
  // brute MS Surface display density fix:   
  size($appWinWidth / displayDensity(), $appWinHeight / displayDensity());
  MAXRAD/=displayDensity();
  MAXSTROKE/=displayDensity();
}

color fgcolor(int hs, int he) { 
  colorMode(HSB, 360, 100, 100);
  return color(random(hs, he), random(50, 100), random(50, 100));
}

void setup() {
  colorMode(HSB, 360, 100, 100);
  $appWinBG =  color(random(150, 210), random(50, 100), 16);
  
  background($appWinBG);
  noFill();
  noCursor();
  frameRate(30);

  minRad = MAXRAD / 8;

  flowers = new Flower[FLOWER_NUM];
  polys = new Poly[POLY_NUM];

  colorMode(HSB, 360, 100, 100);

  for (int i=0; i<FLOWER_NUM; i++) {
    flowers[i] = new Flower(
      int(random(width,width*2)), int(random(0,height)),    // pos
      minRad, random(minRad,MAXRAD),                        // radius
      int(random(2, random(MAXPETALS/2, MAXPETALS))),       // petals
      random(-PI, PI),                                      // st ang
      random(1, MAXSPD),                                    // linear vel
      fgcolor(0, 120), int(random(2, MAXSTROKE))            // color, stroke
      );
  }

  for (int i=0; i<POLY_NUM; i++) {
    polys[i] = new Poly(
      int(random(width,width*2)), int(random(0,height)),    // pos
      minRad, random(minRad,MAXRAD),                        // radius
      int(random(3, random(MAXSIDES/2, MAXSIDES))),         // petals
      random(-PI, PI),                                      // st ang
      random(1, MAXSPD),                                    // linear vel
      fgcolor(60, 180), int(random(2, MAXSTROKE))           // color, stroke
      );
       
  }


}


/*
 DRAW
 */
void draw() {
  for (int i=0; i<polys.length; i++) {
    polys[i].draw();
  } 

  windowBlur($appWinBG, 96);

  for (int i=0; i<flowers.length; i++) {
    flowers[i].draw();
  } 

  if ($saveFrameNum > 0 && 
    frameCount > $saveFrameOffset && frameCount - $saveFrameOffset <= $saveFrameNum)
      saveFrame("frames/#####.tga");
    
}

/* polygons */

class Poly {
  PVector position;
  float minrad, maxrad, rad, radf, radg, strot, rot, avel, xvel;
  int strokew, sides, ct;
  color col;

  Poly(int x, int y, float mird, float mxrd, int p, float sr, float xv, color c, int sw) {
    ct = 0;
    position = new PVector(x, y);
    minrad = mird;
    maxrad = mxrd;
    rad = random(minrad, maxrad);
    radg = 0;
    strot = sr;
    rot = 0;
    xvel = xv;
    avel = xv/30;
    avel = sr >=0 ? avel : 0-avel;
    sides = p;
    col = c;
    strokew = sw;
  }

  void draw() {
    if (abs(rot) < TAU) ct++;
    radg = sin(abs(strot));
    
    strot+=avel/10;
    rot = 0;
    position.x-=xvel;
    radf = lerp(minrad, maxrad, abs(sin(strot)))/maxrad;
    
    if (position.x < 0-maxrad*2) {
      ct = 0;
      radg = 0;
      position = new PVector(int(random(width,width*2)), int(random(0,height)));
      avel = 0 - avel;
      strokew = int(random(2, MAXSTROKE));
      sides = int(random(2, MAXPETALS));

      return;
    }

    blendMode(SCREEN);
    stroke(col, 24);
    strokeWeight(strokew);
    noFill();

    pushMatrix();
    translate(position.x, position.y);
    rotate(strot);
    
    for (int i = 0; i < ct; i+=30) {
      rot+=avel;
      rad = lerp(minrad, maxrad, abs(sin(rot*sides)));

      polygon(0,0, rad*radf*radg, sides);
      
    }
    popMatrix();

  }
}


/* our flower figure */

class Flower {
  PVector position, angvec, drawto;
  float minrad, maxrad, rad, radf, radg, strot, rot, avel, xvel;
  int strokew, petals, ct;
  color col;

  Flower(int x, int y, float mird, float mxrd, int p, float sr, float xv, color c, int sw) {
    ct = 0;
    position = new PVector(x, y);
    minrad = mird;
    maxrad = mxrd;
    rad = random(minrad, maxrad);
    radg = 0;
    strot = sr;
    rot = 0;
    xvel = xv;
    avel = xv/30;
    avel = sr >=0 ? avel : 0-avel;
    petals = p;
    col = c;
    strokew = sw;
  }

  void draw() {
    if (abs(rot) < TAU) ct++;
    radg = sin(abs(strot));
    
    strot+=avel/10;
    rot = 0;
    position.x-=xvel;
    radf = lerp(minrad, maxrad, abs(sin(strot)))/maxrad;
    
    if (position.x < 0-maxrad*2) {
      ct = 0;
      radg = 0;
      position = new PVector(int(random(width,width*2)), int(random(0,height)));
      avel = 0 - avel;
      strokew = int(random(2, MAXSTROKE));
      petals = int(random(2, MAXPETALS));

      return;
    }

    blendMode(SCREEN);
    stroke(col, 96);
    strokeWeight(strokew);
    noFill();

    pushMatrix();
    translate(position.x, position.y);
    rotate(rot);

    for (int i = 0; i < ct; i++) {
      rot+=avel;
      rad = lerp(minrad, maxrad, abs(sin(rot*petals)));
            
      drawto = PVector.fromAngle(strot+rot).setMag(rad*radf*radg);

      line(0, 0, drawto.x, drawto.y);
    }

    popMatrix();

  }
}

/* from the Regular Polygon example */

void polygon(float x, float y, float radius, int npoints) {
  float angle = TWO_PI / npoints;
  beginShape();
  for (float a = 0; a < TWO_PI; a += angle) {
    float sx = x + cos(a) * radius;
    float sy = y + sin(a) * radius;
    vertex(sx, sy);
  }
  endShape(CLOSE);
}


/* Full window blur */
void windowBlur(color bg, int opacity) {
   blendMode(BLEND);
   noStroke();
   fill(bg, opacity);
   rectMode(CORNER);
   rect(0,0, width, height);
   noFill();
}