OpenSCAD source code: Entrance reducer for oval bird box opening

Oval Entrance Reducer.scad

// Bird Box - oval entrance reducer
// Ed Nisley KE4ZNU 2020-02-12

//- Extrusion parameters must match reality!
//  Print with 3 shells and 3 solid layers

ThreadThick = 0.25;
ThreadWidth = 0.40;

HoleWindage = 0.2;

function IntegerMultiple(Size,Unit) = Unit * ceil(Size / Unit);

Protrusion = 0.1;           // make holes end cleanly

inch = 25.4;

//----------------------
// Dimensions

EntranceID = 1.25 * inch;

BoxHole = [1.5,2.25] * inch;
BoxWall = 0.75 * inch;

HoleOC = BoxHole.y - BoxHole.x;

FlangeWidth = 5.0;
FlangeThick = 5*ThreadThick;

$fn = 12*4;

//-------------------
// Build it

difference() {
  union() {
    linear_extrude(height=BoxWall + FlangeThick)
      hull()
        for (j=[-1,1])
          translate([0,j*HoleOC/2])
            circle(d=BoxHole.x);
    linear_extrude(height=FlangeThick)
      hull()
        for (j=[-1,1])
          translate([0,j*HoleOC/2])
            circle(d=BoxHole.x + 2*FlangeWidth);
  }
  translate([0,0,-Protrusion])
    cylinder(d=EntranceID,h=2*BoxWall);
}

More details on my blog at https://wp.me/poZKh-8Ms