OpenSCAD source code: Adapters for aluminum tube patio chair feet

Patio Chair Foot Adapters.scad

// Patio chair foot adapter
// Ed Nisley - KE4ZNU - 2023-06

include <BOSL2/std.scad>
include <BOSL2/threading.scad>

LegAngles = [5,15];

/* [Hidden] */

ThreadThick = 0.25;
ThreadWidth = 0.40;

HoleWindage = 0.2;

Protrusion = 0.1;     // make holes end cleanly

function IntegerMultiple(Size,Unit) = Unit * ceil(Size / Unit);

ID = 0;
OD = 1;
LENGTH = 2;

inch = 25.4;

//----------------------
// Dimensions

LegTube = [18.8 - HoleWindage,22.5,0];

Stud = [8.0,1.25,10.0];           // M8x1.25 foot stud

FlangeBase = 3.0;

//-----------------------


for (i=[0:len(LegAngles)-1]) {

  ang = LegAngles[i];

  FlangeIncr = LegTube[OD]*tan(ang);
  Flange = [Stud[0],LegTube[OD],FlangeBase + FlangeIncr];

  translate([i*1.5*Flange[OD],0,0])
    difference() {
      translate([0,0,0*-FlangeIncr/2])
        threaded_nut(2*Flange[OD],Stud[0],1.5*Stud[2],Stud[1],
          anchor=BOTTOM,bevel=false,$slop=0.2);
      rotate([0,ang,0]) {
        translate([0,0,FlangeBase + FlangeIncr/2])
          tube(4*Stud[2],2*Flange[OD],LegTube[ID]/2,
              anchor=BOTTOM);
        tube(4*Stud[2],2*Flange[OD],Flange[OD]/2,
              anchor=CENTER);
      }
      cube([Flange[OD],ThreadWidth,2*ThreadThick],anchor=BOTTOM+RIGHT);
    }
}

More details on my blog at https://softsolder.com/2023/06/29/patio-chair-foot-adapters/