OpenSCAD source code: Enlarged pads for photo backdrop spring clamps

Spring Clamp Pads.scad

// Clamp pads for Emart photo backdrop clamps
// Ed Nisley KE4ZNU Jan 2021

/* [Hidden] */

ThreadThick = 0.25;
ThreadWidth = 0.40;

HoleWindage = 0.2;

Protrusion = 0.1;      // make holes end cleanly

inch = 25.4;

function IntegerMultiple(Size,Unit) = Unit * ceil(Size / Unit);

module PolyCyl(Dia,Height,ForceSides=0) {      // based on nophead's polyholes
  Sides = (ForceSides != 0) ? ForceSides : (ceil(Dia) + 2);
  FixDia = Dia / cos(180/Sides);
  cylinder(d=(FixDia + HoleWindage),h=Height,$fn=Sides);
}

//----------------------
// Dimensions

OEMpad = [24.0,16.0,3.0];               // original pad

Pad = [35.0,25.0,8.0 + OEMpad.z];       // pad extension

PadOffset = [0,-3.0,0];

CornerRad = 3.0;                        // corner rounding

Gap = 3.0;

//----------------------
// Shape the pad

module BigPad() {

  difference() {

    hull()
      for (i=[-1,1],j=[-1,1],k=[-1,1])
        translate([i*(Pad.x/2 - CornerRad),j*(Pad.y/2 - CornerRad),k*(Pad.z/2 - CornerRad) + Pad.z/2])
          sphere(r=CornerRad,$fn=6);

    translate(PadOffset + [0,0,Pad.z - (OEMpad.z + Protrusion)/2])
      cube(OEMpad + [HoleWindage,HoleWindage,Protrusion],center=true);

  }

}

//----------------------
// Build a pair

translate([0,(Pad.y + Gap)/2,0])
  BigPad();

translate([0,-(Pad.y + Gap)/2,0])
  rotate(180)
    BigPad();

More details on my blog at https://wp.me/poZKh-9LU