A script to empty and delete buckets

s3_bucket_remover.clj

#!/usr/bin/env bb

(require '[babashka.pods :as pods])

(pods/load-pod 'org.babashka/aws "0.0.6")

(require '[pod.babashka.aws :as aws])
(require '[pod.babashka.aws.credentials :as credentials])

(def region "us-east-1")

(def s3-client
  (aws/client {:api :s3 :region region
               :credentials-provider (credentials/basic-credentials-provider
                                      {:access-key-id     ""
                                       :secret-access-key ""})}))

(defn list-objects [bucket]
  (aws/invoke s3-client {:op :ListObjects
                         :request {:Bucket bucket}}))

(defn objects->keys [objects]
  (map #(select-keys % [:Key]) (:Contents objects)))

(defn clear-s3-results
  [bucket]
  (loop [next-set (objects->keys (list-objects bucket))
         deleted-objects []]
    (if (pos? (count next-set))
      (let [deleted (aws/invoke s3-client  {:op :DeleteObjects
                                            :request {:Bucket bucket
                                                      :Delete {:Objects next-set}}})]
        (recur (objects->keys (list-objects bucket))
               (apply conj deleted-objects (:Deleted deleted))))
      deleted-objects)))

(defn delete-s3-bucket [bucket]
  (aws/invoke s3-client {:op :DeleteBucket
                         :request {:Bucket bucket}}))

(defn empty-and-delete-bucket [bucket]
  (clear-s3-results bucket)
  (delete-s3-bucket bucket))


(defn bucket-names [buckets]
  (map :Name buckets))

(defn empty-and-delete-buckets []
  (let [{:keys [Buckets]} (aws/invoke s3-client {:op :ListBuckets})
        bucket-names (bucket-names Buckets)]
    (pmap
     empty-and-delete-bucket
     bucket-names)))

(empty-and-delete-buckets)

Solution from Slack:

Yeah, in my gist I set the region in the client. But apparently, when getting the buckets with this client, it gives back buckets in other regions as well. If I then try to list object from a bucket outside that region this error occurs. The solution is to retrieve the region by calling GetBucketLocation and add that to the list objects request