Angular Resource - Share all instances of a query across entire app

app.coffee

app = angular.module 'my-app', ['eo-cached-resource-action']

app.factory 'Category', ($resource, cachedResourceAction) ->
  Category = $resource "/categories/:id/:action", {id: '@id'}, {
    query: { method: 'GET', cache: true, isArray: true }
  }

  Category.query = cachedResourceAction.wrapArrayAction(Category.query)
  
  Category

# Usage as usual:

$scope.categories = Category.query()

# or

Category.query (categories) ->
  $scope.categories = categories

# or

Category.query().$promise.then (categories) ->
  $scope.categories = categories

eo-cached-resource-action.coffee

app = angular.module 'eo-cached-resource-action', []

app.factory 'cachedResourceAction', ($q) ->
  arrayResult: ->
    value = []
    value.$resolved = false
    deferred = $q.defer()
    value.$promise = deferred.promise
    value.$$promise = deferred
    value

  resolveArrayResult: (value, items) ->
    value.$resolved = true
    value.length = 0
    Array::push.apply(value, items)
    value.$$promise.resolve(value)

  wrapArrayAction: (resourceActionFn) ->
    _loading = false

    _cachedValue = @arrayResult()

    (callback) =>
      if _cachedValue.$resolved
        _cachedValue.$$promise.resolve(_cachedValue)
      else
        _cachedValue.$promise.then(callback) if callback

        if !_loading
          # this happens only once
          _loading = true
          resourceActionFn (items) =>
            _loading = false

            @resolveArrayResult(_cachedValue, items)

      _cachedValue


# TODO: ability to invalidate cache