PKGBUILD for gpaste 2.5

PKGBUILD

# Maintainer:  Elder Marco <eldermarco at gmail dot com>

pkgname=gpaste
pkgver=2.5
pkgrel=1
pkgdesc="Clipboard management system with a gnome-shell extension"

license=('GPL3')
url="https://github.com/Keruspe/GPaste"
source=("https://github.com/downloads/Keruspe/GPaste/$pkgname-$pkgver.tar.xz")

makedepends=('dbus-core' 'libxml2' 'libxcb' 'xcb-util-keysyms' 'gtk3' 'vala' 'intltool')
options=(!libtool)

depends=('dbus-core' 'libxml2' 'gtk3' 'gnome-shell>=3.4')
install=$pkgname.install

arch=('i686' 'x86_64')
md5sums=('44ddc08c5c03151867623da3cce06846')

build () {
    cd "$srcdir/$pkgname-$pkgver"

    ./configure --prefix=/usr           \
                --sysconfdir=/etc       \
                --libexecdir=/usr/lib   \
                --enable-vala           \
                --disable-static        \
                --disable-applet        \
                --disable-schemas-compile
    make
}

package () {
    cd "$srcdir/$pkgname-$pkgver"
    make DESTDIR="$pkgdir" install

    # bash/zsh completion support
    install -Dp -m0644 data/completions/$pkgname     \
        "$pkgdir/etc/bash_completion.d/$pkgname"
    install -Dp -m0644 data/completions/_$pkgname    \
        "$pkgdir/usr/share/zsh/site-functions/_$pkgname"
}
# expandtab:tabstop=4:shiftwidth=4