Awk script to generate SQL inserts from tab file

generate_insert_statements.awk

#!/usr/bin/gawk -f

BEGIN {
    if (!table) {
        print "usage: generate_insert_statements.awk -v table=TARGET_TABLE_NAME [datafiles ...]" > "/dev/stderr"
        failed = 1
        exit 1
    }
    FS = FS ? FS : "\t"
    freq = freq ? freq : 100
}

NR == 1 {
    column_count = split($0, columns)
    insert_clause = "INSERT INTO " table " ("
    for (i = 1; i < column_count; i++)
        insert_clause = insert_clause columns[i] ", "
    insert_clause = insert_clause columns[i] ") VALUES "
    print "START TRANSACTION;"
}

NR > 1 {
    values_clause = length($1) ? "('" $1 "'" : "NULL"
    for (i = 2; i <= column_count; i++) {
        value = length($i) ? "'" $i "'" : "NULL"
        values_clause = values_clause ", " value
    }
    values_clause = values_clause ");"
    print insert_clause values_clause
}

NR % freq == 0 {
    print "COMMIT;"
    print "START TRANSACTION;"
}

END {
    if (!failed)
        print "COMMIT;"
}