Installs and Runs the Android app from Gradle

build.gradle.kts

androidComponents {
    val adbPath = sdkComponents.adb.get().asFile.absolutePath

    onVariants { variant ->
        val capitalizedVariantName = variant.name.replaceFirstChar(Char::titlecase)
        val applicationId = variant.applicationId.get()

        tasks.register("run${capitalizedVariantName}") {
            group = "run"
            description = "Installs and Launches the $capitalizedVariantName build"

            dependsOn("install${capitalizedVariantName}")
            dependsOn("launch${capitalizedVariantName}")
        }

        tasks.register<Exec>("launch${capitalizedVariantName}") {
            group = "run"
            description = "Launches the $capitalizedVariantName build"

            mustRunAfter("install${capitalizedVariantName}")

            doFirst {
                println("Launching $applicationId")
                println("execute: ${commandLine.joinToString(" ")}")
            }

            commandLine = listOf(
                adbPath,
                "shell", "am", "start",
                "-p", applicationId,
                "-a", "android.intent.action.MAIN",
                "-c", "android.intent.category.LAUNCHER",
            )
        }
    }
}