Optimized Re-frame schema validation/check - ClojureScript, malli

fast-re-frame-schema-check.cljs

(ns interceptors
  (:require
   [clojure.data :as d]
   [malli.core :as m]
   [malli.error :as me]))

(def prev-state (atom nil))

;; Applies schema only changed parts (diff) of the app-db (state)
(defn check-and-throw [schema state event]
  (if @prev-state
    (let [[things-only-in-prev things-only-in-current _] (d/diff @prev-state state)
          changed-keys (set (concat (keys things-only-in-prev) (keys things-only-in-current)))]
      (reset! prev-state state)
      (when (seq changed-keys)
        (let [schema* (->> schema
                           (rest)
                           (filter (fn [[schema-key & _]] (changed-keys schema-key)))
                           (cons :map)
                           (vec))]
          (when-not (m/validate schema* state)
            (js/console.error (str "Event: " (first event)))
            (throw (js/Error. (str "Schema check failed: " (me/humanize (m/explain schema* state)))))))))
    (do
      (reset! prev-state state)
      (when-not (m/validate schema state)
        (js/console.error (str "Event: " (first event)))
        (throw (js/Error. (str "Schema check failed at startup: " (me/humanize (m/explain schema state)))))))))