clojure string interpolation for selmer

(ns escherize.kenning
  (:require [selmer.parser :as parser]))

(defmacro ^:private env-map []
  `(apply zipmap [(mapv keyword (quote ~(keys &env))) (vector ~@(keys &env))]))

(defn ^:private resolve-kw [env kw]
  (when-let [found-sym (or
                        (get env kw nil)
                        (try (eval (symbol kw))
                             (catch java.lang.RuntimeException _ nil)))]
    {kw found-sym}))

(defmacro <<
  "Resolves the variables from your template string from the local-env, or the
  namespace and puts them into your template for you.

  e.g. (let [a 1] (<< \"{{a}} + {{a}} = 2\")) ;;=> \"1 + 1 = 2\" "
  [s]
  `(->> (parser/known-variables ~s)
        (mapv #(resolve-kw (env-map) %))
        (apply merge)
        (parser/render ~s)))

(comment

  (def user "henry")

  (<< "Oh, {{user}}!")
  ;;=> "Oh, henry!"

  (let [user "john"]
    (<< "{{user}}ny appleseed"))
  ;;=> "johnny appleseed"

  (<< "{{user}}")
  ;; <= converts to =>
  (parser/render "{{user}}" {:user user})
  ;; <= converts to =>
  (parser/render "{{user}}"
                 (->> "{{user}}"
                      parser/known-variables
                      (mapv #(resolve-kw (env-map) %))
                      (apply merge))))