Get findspots for denarii minted from 100 to 50 B.C.
This file contains bidirectional Unicode text that may be interpreted or compiled differently than what appears below. To review, open the file in an editor that reveals hidden Unicode characters.
Learn more about bidirectional Unicode characters
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#> | |
PREFIX dcmitype: <http://purl.org/dc/dcmitype/> | |
PREFIX dcterms: <http://purl.org/dc/terms/> | |
PREFIX foaf: <http://xmlns.com/foaf/0.1/> | |
PREFIX geo: <http://www.w3.org/2003/01/geo/wgs84_pos#> | |
PREFIX nm: <http://nomisma.org/id/> | |
PREFIX nmo: <http://nomisma.org/ontology#> | |
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#> | |
SELECT DISTINCT ?object ?type ?findspot ?lat ?long ?name ?closingDate WHERE { | |
?coinType nmo:hasDenomination nm:denarius ; | |
nmo:hasEndDate ?date . | |
FILTER ( ?date >= "-0100"^^xsd:gYear && ?date <= "-0050"^^xsd:gYear ) . | |
{ ?object nmo:hasTypeSeriesItem ?coinType ; | |
rdf:type nmo:NumismaticObject ; | |
nmo:hasFindspot ?findspot } | |
UNION { ?object nmo:hasTypeSeriesItem ?coinType ; | |
rdf:type nmo:NumismaticObject ; | |
dcterms:isPartOf ?hoard . | |
?hoard nmo:hasFindspot ?findspot } | |
UNION { ?contents nmo:hasTypeSeriesItem ?coinType ; | |
a dcmitype:Collection . | |
?object dcterms:tableOfContents ?contents ; | |
nmo:hasFindspot ?findspot } | |
?object a ?type . | |
?findspot geo:lat ?lat . | |
?findspot geo:long ?long . | |
OPTIONAL { ?findspot foaf:name ?name } | |
OPTIONAL { ?object nmo:hasClosingDate ?closingDate } | |
} ORDER BY ?date |
Sign up for free
to join this conversation on GitHub.
Already have an account?
Sign in to comment