Skip to content

Instantly share code, notes, and snippets.

Embed
What would you like to do?
Seleucid Coinage British Museum SPARQL query
PREFIX bmo: <http://collection.britishmuseum.org/id/ontology/>
PREFIX crm: <http://erlangen-crm.org/current/>
PREFIX ecrm: <http://erlangen-crm.org/current/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX bibo: <http://purl.org/ontology/bibo/>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
SELECT ?s ?material ?date ?mint ?authority ?obvType ?revType ?obvLegend ?revLegend ?text WHERE {
?s ecrm:P70i_is_documented_in <http://collection.britishmuseum.org/id/bibliography/6336> FILTER regex(str(?s), "CGR" ,"i") .
OPTIONAL {?s ecrm:P45_consists_of ?consists .
?consists skos:prefLabel ?material }
?s ecrm:P108i_was_produced_by ?prod .
?prod ecrm:P9_consists_of ?p .
OPTIONAL {?p ecrm:P4_has_time-span ?timespan.
?timespan rdfs:label ?date }
OPTIONAL {?p ecrm:P7_took_place_at ?place .
?place skos:prefLabel ?mint}
OPTIONAL {?p ecrm:P17_was_motivated_by ?mot .
?mot skos:prefLabel ?authority }
?s ecrm:P56_bears_feature ?feature .
OPTIONAL {?feature rdfs:label "obverse" ;
bmo:PX_physical_description ?obvType }
OPTIONAL {?feature rdfs:label "reverse" ;
bmo:PX_physical_description ?revType }
?s ecrm:P65_shows_visual_item ?inscriptions .
OPTIONAL {?inscriptions a ecrm:E34_Inscription ;
bmo:PX_inscription_position "obverse" ;
rdfs:label ?obvLegend . FILTER (lang(?obvLegend) != 'en')
}
OPTIONAL {?inscriptions a ecrm:E34_Inscription ;
bmo:PX_inscription_position "reverse" ;
rdfs:label ?revLegend . FILTER (lang(?revLegend) != 'en')
}
OPTIONAL {?s bmo:PX_display_wrap ?text . FILTER regex(?text, "Lorber\\s2002.*::")}
}
Sign up for free to join this conversation on GitHub. Already have an account? Sign in to comment
You can’t perform that action at this time.