Skip to content

Instantly share code, notes, and snippets.

Embed
What would you like to do?
Get all findspots for all hoards or coins associated with silver imperial types
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX dcmitype: <http://purl.org/dc/dcmitype/>
PREFIX dcterms: <http://purl.org/dc/terms/>
PREFIX foaf: <http://xmlns.com/foaf/0.1/>
PREFIX geo: <http://www.w3.org/2003/01/geo/wgs84_pos#>
PREFIX nm: <http://nomisma.org/id/>
PREFIX nmo: <http://nomisma.org/ontology#>
SELECT DISTINCT ?object ?type ?findspot ?lat ?long ?name WHERE {
?coinType nmo:hasMaterial nm:ar ;
dcterms:source nm:ric .
{ ?object nmo:hasTypeSeriesItem ?coinType ;
rdf:type nmo:NumismaticObject ;
nmo:hasFindspot ?findspot }
UNION { ?object nmo:hasTypeSeriesItem ?coinType ;
rdf:type nmo:NumismaticObject ;
dcterms:isPartOf ?hoard .
?hoard nmo:hasFindspot ?findspot }
UNION { ?contents nmo:hasTypeSeriesItem ?coinType ;
a dcmitype:Collection .
?object dcterms:tableOfContents ?contents ;
nmo:hasFindspot ?findspot }
?object a ?type .
?findspot geo:lat ?lat .
?findspot geo:long ?long .
OPTIONAL { ?findspot foaf:name ?name }
}
Sign up for free to join this conversation on GitHub. Already have an account? Sign in to comment
You can’t perform that action at this time.