Symbols from Ecbatana that also appear on types with uncertain mints

uncertain-mint-monograms.sparql

PREFIX crm: <http://www.cidoc-crm.org/cidoc-crm/>
PREFIX dcmitype: <http://purl.org/dc/dcmitype/>
PREFIX dcterms: <http://purl.org/dc/terms/>
PREFIX foaf: <http://xmlns.com/foaf/0.1/>
PREFIX geo: <http://www.w3.org/2003/01/geo/wgs84_pos#>
PREFIX nm: <http://nomisma.org/id/>
PREFIX nmo: <http://nomisma.org/ontology#>
PREFIX org: <http://www.w3.org/ns/org#>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>

SELECT DISTINCT ?altType ?mint ?authority ?date ?symbol   WHERE {
  ?type a nmo:TypeSeriesItem ;
          dcterms:source nm:seleucid_coins ;
          nmo:hasObverse/nmo:hasControlmark|nmo:hasReverse/nmo:hasControlmark ?symbol ;
          nmo:hasMint nm:ecbatana .
  ?altType nmo:hasObverse/nmo:hasControlmark|nmo:hasReverse/nmo:hasControlmark ?symbol ;
           nmo:hasMint ?mint ;
           nmo:hasAuthority ?authority ;
           nmo:hasStartDate ?date .
  ?mint a nmo:Mint .
  FILTER NOT EXISTS {?mint geo:location ?loc}
  FILTER NOT EXISTS {?mint skos:broader ?broader . ?broader a nmo:Mint}
} ORDER BY ?date