Republican coins with RRC numbers in the Getty

getty-rrc.sparql

PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX crm: <http://www.cidoc-crm.org/cidoc-crm/>
PREFIX getty: <https://data.getty.edu/>
prefix getty-media: <https://media.getty.edu/>
PREFIX aat: <http://vocab.getty.edu/aat/>
PREFIX la:<https://linked.art/ns/terms/>
PREFIX crmsci:	<http://www.ics.forth.gr/isl/CRMsci/>

SELECT ?coin ?accession ?name ?dor ?weight ?diameter ?found ?ref WHERE {
  ?coin crm:P2_has_type aat:300037222 ;
        crm:P67i_is_referred_to_by ?citation ;
        crm:P1_is_identified_by ?id1, ?id2 ;
        rdfs:label ?name;
        rdf:type crm:E22_Human-Made_Object .
  OPTIONAL {?coin crm:P43_has_dimension ?dim1 .
  ?dim1 crm:P2_has_type aat:300056240 ;
        crm:P91_has_unit aat:300379226; 
        crm:P90_has_value ?weight}
  OPTIONAL {?coin crm:P43_has_dimension ?dim2 .
  ?dim2 crm:P2_has_type aat:300055624 ; 
        crm:P90_has_value ?diameter}
  OPTIONAL {?coin crmsci:O19i_was_object_found_by ?found}
  ?id1 crm:P2_has_type <https://data.getty.edu/museum/ontology/linked-data/dor-id> ;
       crm:P190_has_symbolic_content ?dor.
  ?id2 crm:P2_has_type aat:300312355 ;
       crm:P190_has_symbolic_content ?accession.
  ?citation crm:P2_has_type <http://vocab.getty.edu/aat/300418049> ;
            crm:P190_has_symbolic_content ?ref FILTER (regex(?ref, "^Crawford"))
}