compose-overrides.nix

{ pkgs, old, newPackageOverride }:
if old ? packageOverrides
then pkgs.lib.composeExtensions old.packageOverrides newPackageOverride
else newPackageOverride

overlay.nix

let
  composePackageOverrides = import ./lib/compose-overrides.nix;
  packageOverrides = python-self: python-super: {
    pyopenssl = python-super.pyopenssl.overridePythonAttrs (old: {
      version = "20.0.1";
      src = python-super.fetchPypi {
        pname = "pyOpenSSL";
        version = "20.0.1";
        sha256 = "0labcbh2g0jhgisd79wx9kixmi6fip28096d1xb05fj3jmsiq8sc";
      };
    });
    cryptography = python-super.cryptography.overridePythonAttrs (old: {
      version = "3.2.1";
      src = python-super.fetchPypi {
        version = "3.2.1";
        pname = "cryptography";
        sha256 = "sha256:1qxz02kfsrihq1h4afyqwcsv9nh3s9mmrr6y9lhi4angw05y3mfk";
      };
      patches = [];
    });
    cryptography_vectors = python-super.cryptography_vectors.overridePythonAttrs (old: {
      version = "3.2.1";
      src = python-super.fetchPypi {
        version = "3.2.1";
        pname = "cryptography_vectors";
        sha256 = "sha256:12dq1grn0bjj7c6sj6apd6328525n7xq4kbbmww63sn3x7081vls";
      };
    });
  };
in
self: super: {
  openssl_1_1 = super.openssl_1_1.overrideAttrs (old: rec {
    version = "1.1.1k";
    pname = "openssl";
    name = "${pname}-${version}";
    src = builtins.fetchurl {
      url = "https://www.openssl.org/source/${pname}-${version}.tar.gz";
      sha256 = "1rdfzcrxy9y38wqdw5942vmdax9hjhgrprzxm42csal7p5shhal9";
    };
  });

  python2 = super.python2.override (old: {
    packageOverrides = composePackageOverrides {
      pkgs = super;
      inherit old;
      newPackageOverride = packageOverrides;
    };
  });

  python3 = super.python3.override (old: {
    packageOverrides = composePackageOverrides {
      pkgs = super;
      inherit old;
      newPackageOverride = packageOverrides;
    };
  });
}