nixos_openssl-111k.nix

self: super: rec {
  openssl_1_1 = super.openssl_1_1.overrideAttrs (old: rec {
    version = "1.1.1k";
    pname = "openssl";
    name = "${pname}-${version}";
    src = builtins.fetchurl {
      url = "https://www.openssl.org/source/${pname}-${version}.tar.gz";
      sha256 = "1rdfzcrxy9y38wqdw5942vmdax9hjhgrprzxm42csal7p5shhal9";
    };
  });
  openssl = openssl_1_1;
}

nixpkgs.json

{ "name": "nixpkgs"
, "url": "https://github.com/NixOS/nixpkgs-channels/archive/353333ef340952c05332e3c271dff953264cb017.tar.gz"
, "sha256": "sha256:0bv34yz892yxhx2kb8a1yr5pm0g8ck5w021yj87r7kfnp416apdh"
}

shell.nix

let
  nixpkgs-pin = builtins.fromJSON (builtins.readFile ./nixpkgs.json);
  nixpkgs-src = builtins.fetchTarball nixpkgs-pin;
  nixpkgs = import nixpkgs-src {
    overlays = [ (import ./nixos/openssl-111k.nix) ];
  };
in
{ pkgs ? nixpkgs }:
let
  # Get a version of Morph known to work with our version of NixOS.                                                                                                                           
  morph-src = pkgs.fetchFromGitHub {
    owner = "DBCDK";
    repo = "morph";
    rev = "3856a9c2f733192dee1600b8655715d760ba1803";
    hash = "sha256:0jhypvj45yjg4cn4rvb2j9091pl6z5j541vcfaln5sb3ds14fkwf";
  };
  morph = pkgs.callPackage (morph-src + "/nix-packaging") { };
in
pkgs.mkShell {
  NIX_PATH = "nixpkgs=${nixpkgs.path}";
  buildInputs = [
    morph
  ];
}