javapackager with Gradle

build.gradle

group 'de.muspellheim'
version '1.0.0'

apply plugin: 'java'

sourceCompatibility = 1.8
compileJava.options.encoding = 'UTF-8'

repositories {
    jcenter()
}

dependencies {
    compile 'org.postgresql:postgresql:42.1.4'
    testCompile 'junit:junit:4.+'
}

def mainClassName = 'de.muspellheim.application.App'
def embeddedJRE = false

jar {
    manifest {
        attributes(
                'Main-Class': mainClassName,
                'Class-Path': configurations.runtime.collect { it.getName() }.join(' ')
        )
    }
}

task copyDependencies(type: Copy) {
    destinationDir libsDir
    from configurations.runtime
}

task javapackager(type: Exec, dependsOn: [assemble, copyDependencies]) {
    def nativeType
    if (System.properties['os.name'].toLowerCase().contains('windows'))
        nativeType = 'msi'
    if (System.properties['os.name'].toLowerCase().contains('mac'))
        nativeType = 'dmg'
    if (System.properties['os.name'].toLowerCase().contains('linux'))
        nativeType = 'rpm'

    def dependencies = []
    configurations.runtime.forEach({ file ->
        dependencies.add('-srcfiles')
        dependencies.add(file.getName())
    })

    def paramEmbeddedJRE = embeddedJRE ? [] : ['-Bruntime=']

    workingDir project.projectDir
    commandLine = [
            'javapackager',
            '-deploy',
            '-nosign',
            '-native', nativeType,
            '-outdir', "${buildDir}/distribution",
            '-outfile', project.name,
            '-name', 'Application Seed',
            '-appclass', mainClassName,
            '-srcdir', libsDir,
            '-srcfiles', jar.archiveName
    ] + dependencies + paramEmbeddedJRE
}

You're a champ - thank you for this.