esp-07 based wifi to uart bridge

esp-07-wifi2uart.md

parts

• hardware
  • esp-07 based wifi 2 uart board
  • ufl/ipex antennas (optional)
    • pcb based
    • pcb based#2
    • arial/dipole/whip
• usb serial or ftdi adapter
• software
  • Arduino IDE (1.8.5 used)
  • Arduino core for ESP8266 WiFi chip

install

• install arduino ide (next->next->finish)

• install esp8266 boards

• setup board config:

  

• use following sketch

#include <ESP8266WiFi.h>
#include <WiFiUDP.h>

#define ssid "fape-chorus"
#define pw "12345678"

#define baudRate 115200
#define serialTimeout 10
#define port 9000
IPAddress localIp(192, 168, 4, 1);

IPAddress netmask(255, 255, 255, 0);
char packet[UDP_TX_PACKET_MAX_SIZE] ={};
WiFiUDP Server;
IPAddress remoteIP;
int remotePort = 0;
int len = 0;

void setup() {
    //clear buffer
    memset(packet, 0, sizeof(packet));
    //setup serial
    Serial.begin(baudRate);
    Serial.setTimeout(serialTimeout);
    //setup AP
    WiFi.mode(WIFI_AP);
    WiFi.softAPConfig(localIp, localIp, netmask);
    WiFi.softAP(ssid, pw);
    WiFi.begin();
    //setup udp server
    Server.begin(port);
}

void loop() {
    // receiver data
    if(Server.parsePacket()) {
        remoteIP = Server.remoteIP();
        remotePort = Server.remotePort();
        len = Server.read(packet, sizeof(packet));
        if(len > 0) {
            Serial.write(packet, len);
        }
    }
    
    // send data
    if(remotePort > 0 && Serial.available()) {
        len = Serial.readBytes(packet, sizeof(packet));
        if(len > 0) {
            Server.beginPacket(remoteIP, remotePort);
            Server.write(packet, len);
            Server.endPacket();
        }
    }
}

• change ssid and pw at the beginning of the sketch
• flip the switch to PROGRAM
• compile and upload
• flip the switch to UART

Chorus RF Laptimer

pcb