Snippets that you can use to deploy stand-alone Java application

build.gradle

def mainClassName = 'sample.app.AppKt'
def embeddedJRE = true

jar {
    manifest {
        attributes(
                'Main-Class': mainClassName,
                'Class-Path': configurations.default.collect { it.getName() }.join(' ')
        )
    }
}

task copyDependencies(type: Copy) {
    from configurations.default
    into "$buildDir/$libsDirName"
}

task javapackager(type: Exec, dependsOn: [assemble, copyDependencies]) {
    def nativeType

    if (System.getProperty("os.name").toLowerCase().contains('windows'))
        nativeType = ['msi']
    else if (System.getProperty("os.name").toLowerCase().contains('mac'))
        nativeType = ['dmg']
    else if (System.getProperty("os.name").toLowerCase().contains('linux'))
        nativeType = ['rpm']
    else
        nativeType = []

    def dependencies = []
    configurations.default.forEach({ file ->
        dependencies.add('-srcfiles')
        dependencies.add(file.getName())
    })

    def paramEmbeddedJRE = embeddedJRE ? [] : ['-Bruntime=']

    workingDir project.projectDir
    commandLine = [
            'javapackager',
            '-deploy',
            '-nosign',
            '-outdir', "${buildDir}/distribution",
            '-outfile', project.name,
            '-name', 'Application Seed',
            '-appclass', mainClassName,
            '-srcdir', "$buildDir/$libsDirName",
            '-srcfiles', jar.archiveFileName.get()
    ] + dependencies + paramEmbeddedJRE + ['-native'] + nativeType
}