PKGBUILD

pkgname=libva1-ubuntu
pkgver=1.7
pkgrel=1
pkgdesc="Old libva from Ubuntu 16.04 for apps not supporting libva2 (esp. Parsec.tv)"
arch=('x86_64')
url="https://linux.palemoon.org"
license=('GPL' 'BSD')
depends=()
mirror="http://archive.ubuntu.com/ubuntu"
source=(
"$mirror/pool/universe/i/intel-vaapi-driver/i965-va-driver_1.7.0-1_amd64.deb"
"$mirror/pool/universe/libv/libva/libva-drm1_1.7.0-1_amd64.deb"
"$mirror/pool/universe/libv/libva/libva-egl1_1.7.0-1_amd64.deb"
"$mirror/pool/universe/libv/libva/libva-glx1_1.7.0-1_amd64.deb"
"$mirror/pool/universe/libv/libva/libva-wayland1_1.7.0-1_amd64.deb"
"$mirror/pool/universe/libv/libva/libva-x11-1_1.7.0-1_amd64.deb"
"$mirror/pool/universe/libv/libva/libva1_1.7.0-1_amd64.deb"
"$mirror/pool/universe/v/vdpau-video/vdpau-va-driver_0.7.4-5_amd64.deb"
)

_get_new_urls() {
	curl http://archive.ubuntu.com/ubuntu/dists/xenial/universe/binary-amd64/Packages.xz \
	 | xzgrep -e Filename \
	 | grep -e libva1 -e libva-[egwx] -e libva-drm1 -e i965-va-driver -e vdpau-va-driver \
	 | cut -d ' ' -f2 \
	 | while read l
	do
		echo '$mirror'/$l
	done
}

package() {
	for f in *.deb
	do
		ar p $f data.tar.xz | tar xJC $pkgdir
	done
	
	rm -rf $pkgdir/usr/share
	find $pkgdir -iname '*.a' -delete
	
	rm -fv $pkgdir/usr/lib/x86_64-linux-gnu/*.so
	mv -v $pkgdir/usr/lib/x86_64-linux-gnu/*.so.1* $pkgdir/usr/lib # move libva so Parsec will find it
	# but keep drivers in original (expected) location for libva1
}
md5sums=('b2607f82422e4de75df474fc4d9ec682'
         'd0455e1f955862e60b28dd6a926c9a19'
         '76afa64c4c6390c27c83e04fbaf5763a'
         'af58cfc1cae586235c09616189bfffe3'
         'c1d54fcc312f51dea259d9e3804b5a6d'
         'bcdd976b32d1d0f615a202b761379497'
         '8b81c77b09b8cb02fa513dc5b72ea762'
         '8362265530432f1de9c3db031b0b8779')