Simple Windows cmd wrapper that allow launch GTA or MTA via Steam

gta_sa_launcher.bat

@ECHO OFF


SET MTA_DIR=C:\Program Files\Steam\steamapps\common\Grand Theft Auto San Andreas\MTA


REM EDITING THE CODE BELOW MAY CAUSE ERRORS

SETLOCAL ENABLEEXTENSIONS ENABLEDELAYEDEXPANSION

SET VERSION=1.01
SET NL=^&ECHO.
SET SA_DIR=%~dp0
SET SA_DIR=%SA_DIR:~0,-1%
SET NEW_EXE="%SA_DIR%\gta-sa.exe"
SET OLD_EXE="%SA_DIR%\gta_sa.exe"

TITLE GTA:SA Terminal Launcher (v%VERSION% 2021-04-09)
MODE CON:COLS=78 LINES=18


IF NOT EXIST %NEW_EXE% (
  CALL :LOGO
  COLOR C0
  ECHO.    ^> NO GTA-SA.EXE^^! DID YOU PLACE ME TO GAME ROOT FOLDER?%NL%%NL%%NL%%NL%%NL%
  ECHO.                          [PRESS ANY KEY TO EXIT]
  PAUSE > NUL
  EXIT
)


COMP /M %COMSPEC% %NEW_EXE% > NUL 2>&1
IF !ERRORLEVEL! == 0 GOTO MENU ELSE GOTO INSTALL


:INSTALL
  CALL :LOGO
  ECHO.    ^> INSTALL THE LAUNCHER?%NL%
  ECHO.      [1]  YES%NL%
  ECHO.      [2]  NO%NL%%NL%
  ECHO.                        [USE NUMBERS TO SELECT OPTIONS]
  CHOICE /N /C:12 > NUL

  IF !ERRORLEVEL! == 1 (
    ( COPY %NEW_EXE% %NEW_EXE%.bak
      COPY %OLD_EXE% %OLD_EXE%.bak
      COPY %NEW_EXE% %OLD_EXE%
      COPY %COMSPEC% %NEW_EXE%
      COMP /M %COMSPEC% %NEW_EXE%
    ) > NUL 2>&1

    IF !ERRORLEVEL! == 1 (
      CALL :LOGO
      COLOR C0
      ECHO.    ^> ERROR^^! TRY RE-RUN THE LAUNCHER AS ADMIN^^!%NL%%NL%%NL%%NL%%NL%%NL%
      GOTO EXIT
    )
  ) ELSE EXIT

  CALL :LOGO
  COLOR 20
  ECHO.    ^> SUCCESS^^! SET NEXT PARAMETER IN STEAM GAME LAUNCH OPTIONS:%NL%
  ECHO.      /K "%~n0%~x0"%NL%%NL%%NL%%NL%
  ECHO.                         [PRESS ANY KEY TO CONTINUE]
  PAUSE > NUL
  GOTO MENU


:MENU
  CALL :LOGO
  ECHO.    [1]  SINGLEPLAYER (GTA_SA.EXE)%NL%
  ECHO.    [2]  MULTIPLAYER (SAMP.EXE)%NL%
  ECHO.    [3]  MULTI THEFT AUTO (MTA.EXE)%NL%%NL%
  ECHO.  [4] SA [5] SAMP [6] MTA [7] AUTHOR                   [8] RESTORE [9] EXIT
  CHOICE /N /C:123456789 > NUL

  IF !ERRORLEVEL! == 1 ( START "" "%SA_DIR%\gta_sa.exe" & GOTO MENU )

  IF !ERRORLEVEL! == 2 ( START "" "%SA_DIR%\samp.exe" & GOTO MENU )

  IF !ERRORLEVEL! == 3 ( START "" "%MTA_DIR%\Multi Theft Auto.exe" & GOTO MENU )

  IF !ERRORLEVEL! == 4 ( START "" "https://store.steampowered.com/app/12120" & GOTO MENU )

  IF !ERRORLEVEL! == 5 ( START "" "https://sa-mp.com" & GOTO MENU )

  IF !ERRORLEVEL! == 6 ( START "" "https://mtasa.com" & GOTO MENU )

  IF !ERRORLEVEL! == 7 ( START "" "https://hexed.pw" & GOTO MENU )

  IF !ERRORLEVEL! == 8 (
    CALL :LOGO
    ECHO.    ^> ARE YOU SURE WANT TO REMOVE THE LAUNCHER?%NL%
    ECHO.      [1]  YES%NL%
    ECHO.      [2]  NO%NL%%NL%
    ECHO.                        [USE NUMBERS TO SELECT OPTIONS]
    CHOICE /N /C:12 > NUL
    IF !ERRORLEVEL! == 1 (
      ( COPY %NEW_EXE%.bak %NEW_EXE%
        COPY %OLD_EXE%.bak %OLD_EXE%
        DEL %NEW_EXE%.bak
        DEL %OLD_EXE%.bak
        COMP /M %COMSPEC% %NEW_EXE%
      ) > NUL 2>&1
      IF !ERRORLEVEL! == 0 (
        CALL :LOGO
        COLOR C0
        ECHO.    ^> ERROR^^! TRY RE-RUN THE LAUNCHER AS ADMIN^^!%NL%%NL%%NL%%NL%%NL%%NL%
        GOTO EXIT
      )
      CALL :LOGO & COLOR 20
      ECHO.    ^> SUCCESS^^! THE LAUNCHER REMOVED^^!%NL%%NL%%NL%%NL%%NL%%NL%
      ECHO.                         [PRESS ANY KEY TO INSTALL]
      PAUSE > NUL
      GOTO INSTALL
    ) ELSE GOTO MENU
  ) 

  IF !ERRORLEVEL! == 9 EXIT


:LOGO
  COLOR F0
  CLS
  ECHO.
  ECHO.     _____ _____ _____    __    _____ _____ _____ _____ _____ _____ _____ 
  ECHO.    ^|   __^|_   _^|  _  ^|  ^|  ^|  ^|  _  ^|  ^|  ^|   ^| ^|     ^|  ^|  ^|   __^| __  ^|
  ECHO.    ^|  ^|  ^| ^| ^| ^|     ^|  ^|  ^|__^|     ^|  ^|  ^| ^| ^| ^|   --^|     ^|   __^|    -^|
  ECHO.    ^|_____^| ^|_^| ^|__^|__^|  ^|_____^|__^|__^|_____^|_^|___^|_____^|__^|__^|_____^|__^|__^|
  ECHO.
  ECHO.                                        TERMINAL LAUNCHER V%VERSION% 2021-04-09
  ECHO.
  ECHO.
  GOTO :EOF


:EXIT
  ECHO.                          [PRESS ANY KEY TO EXIT]
  PAUSE > NUL
  EXIT