flavio-fernandes/mqtt_bug.ino

## mqtt_bug.ino
#include <string.h>
#include <ESP8266WiFi.h>
#include "Adafruit_MQTT.h"
#include "Adafruit_MQTT_Client.h"

/************************* WiFi Access Point *********************************/

//#include "ssidConfig.h"
#define WLAN_SSID       "wifissid"       // Your WiFi AP.
#define WLAN_PASS       "superSecret"    // Your WiFi AP password.
#define MQTT_SERVER     "192.168.1.1"    // Address of MQTT server.
#define MQTT_PORT       1883             // Standard MQTT port 1883.
#define MQTT_USERNAME   ""               // Set to any username for the MQTT server (default none/empty).
#define MQTT_PASSWORD   ""               // MQTT user password (default none/empty).

/************ Global State (you don't need to change this!) ******************/

// Create an ESP8266 WiFiClient class to connect to the MQTT server.
WiFiClient client;

// Setup the MQTT client class by passing in the WiFi client and MQTT server and login details.
Adafruit_MQTT_Client mqtt(&client, MQTT_SERVER, MQTT_PORT, MQTT_USERNAME, MQTT_PASSWORD);

/****************************** Feeds ***************************************/

// Setup a feed for publishing.
Adafruit_MQTT_Publish foo_pub_topic = Adafruit_MQTT_Publish(&mqtt, "/feeds/foo");

// Setup a feed for subscribing to changes.
Adafruit_MQTT_Subscribe foo_sub_topic = Adafruit_MQTT_Subscribe(&mqtt, "/feeds/foo");

// A buffer that has more data than the send packet can handle. It will cause
// a nasty memory corruption. This space has to be big enough to hold the entire
// MQTT packet, which is definitely not going to happen in this example.
char tooMuchData[MAXBUFFERSIZE + 10];

/*************************** Sketch Code ************************************/

// Bug workaround for Arduino 1.6.6, it seems to need a function declaration
// for some reason (only affects ESP8266, likely an arduino-builder bug).
void MQTT_connect();

void setup() {
  Serial.begin(115200);
  delay(10);

  // Fill tooMuchData with 'x'
  memset(tooMuchData, 'x', sizeof(tooMuchData));
  tooMuchData[sizeof(tooMuchData) - 1] = 0;

  Serial.println(F("Adafruit MQTT memory corruption bug demo"));

  // Connect to WiFi access point.
  Serial.println(); Serial.println();
  Serial.print("Connecting to ");
  Serial.println(WLAN_SSID);

  // Set WiFi to station mode
  WiFi.mode(WIFI_STA);
  WiFi.begin(WLAN_SSID, WLAN_PASS);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println();

  Serial.println("WiFi connected");
  Serial.println("IP address: "); Serial.println(WiFi.localIP());

  // Setup MQTT subscription for sub_topic feed.
  mqtt.subscribe(&foo_sub_topic);
}

void loop() {
  // Ensure the connection to the MQTT server is alive (this will make the first
  // connection and automatically reconnect when disconnected).  See the MQTT_connect
  // function definition further below.
  MQTT_connect();

  // Publish a buffer so big, it will corrupt the members of the mqtt
  // instance. That includes the subscription member. Boom! :) :)
  Serial.print(F("\nSending foo_pub_topic val "));
  Serial.print("...");
  if (! foo_pub_topic.publish(tooMuchData)) {
    Serial.println(F("Failed"));
  } else {
    Serial.println(F("OK!"));
  }

  delay(3000);

  // Now try to look at packets we subscribed to and see it
  // hit a LoadProhibited exception.
  Adafruit_MQTT_Subscribe *subscription;
  while ((subscription = mqtt.readSubscription(5000))) {
    if (subscription == &foo_sub_topic) {
      Serial.print(F("Got: "));
      Serial.println((char *)foo_sub_topic.lastread);
    }
  }

  // Will likely never make it here if you have bug described in
  // https://github.com/adafruit/Adafruit_MQTT_Library/issues/122
  Serial.println(F("Bug must have been fixed. Nice!"));
}

// Function to connect and reconnect as necessary to the MQTT server.
// Should be called in the loop function and it will take care if connecting.
void MQTT_connect() {
  int8_t ret;

  // Stop if already connected.
  if (mqtt.connected()) {
    return;
  }

  Serial.print("Connecting to MQTT... ");

  uint8_t retries = 3;
  while ((ret = mqtt.connect()) != 0) { // connect will return 0 for connected
       Serial.println(mqtt.connectErrorString(ret));
       Serial.println("Retrying MQTT connection in 5 seconds...");
       mqtt.disconnect();
       delay(5000);  // wait 5 seconds
       retries--;
       if (retries == 0) {
         // basically die and wait for WDT to reset me
         while (1);
       }
  }
  Serial.println("MQTT Connected!");
}
	#include <string.h>
	#include <ESP8266WiFi.h>
	#include "Adafruit_MQTT.h"
	#include "Adafruit_MQTT_Client.h"

	/*********************** WiFi Access Point *******************************/

	//#include "ssidConfig.h"
	#define WLAN_SSID "wifissid" // Your WiFi AP.
	#define WLAN_PASS "superSecret" // Your WiFi AP password.
	#define MQTT_SERVER "192.168.1.1" // Address of MQTT server.
	#define MQTT_PORT 1883 // Standard MQTT port 1883.
	#define MQTT_USERNAME "" // Set to any username for the MQTT server (default none/empty).
	#define MQTT_PASSWORD "" // MQTT user password (default none/empty).

	/********** Global State (you don't need to change this!) ****************/

	// Create an ESP8266 WiFiClient class to connect to the MQTT server.
	WiFiClient client;

	// Setup the MQTT client class by passing in the WiFi client and MQTT server and login details.
	Adafruit_MQTT_Client mqtt(&client, MQTT_SERVER, MQTT_PORT, MQTT_USERNAME, MQTT_PASSWORD);

	/**************************** Feeds *************************************/

	// Setup a feed for publishing.
	Adafruit_MQTT_Publish foo_pub_topic = Adafruit_MQTT_Publish(&mqtt, "/feeds/foo");

	// Setup a feed for subscribing to changes.
	Adafruit_MQTT_Subscribe foo_sub_topic = Adafruit_MQTT_Subscribe(&mqtt, "/feeds/foo");

	// A buffer that has more data than the send packet can handle. It will cause
	// a nasty memory corruption. This space has to be big enough to hold the entire
	// MQTT packet, which is definitely not going to happen in this example.
	char tooMuchData[MAXBUFFERSIZE + 10];

	/************************* Sketch Code **********************************/

	// Bug workaround for Arduino 1.6.6, it seems to need a function declaration
	// for some reason (only affects ESP8266, likely an arduino-builder bug).
	void MQTT_connect();

	void setup() {
	Serial.begin(115200);
	delay(10);

	// Fill tooMuchData with 'x'
	memset(tooMuchData, 'x', sizeof(tooMuchData));
	tooMuchData[sizeof(tooMuchData) - 1] = 0;

	Serial.println(F("Adafruit MQTT memory corruption bug demo"));

	// Connect to WiFi access point.
	Serial.println(); Serial.println();
	Serial.print("Connecting to ");
	Serial.println(WLAN_SSID);

	// Set WiFi to station mode
	WiFi.mode(WIFI_STA);
	WiFi.begin(WLAN_SSID, WLAN_PASS);
	while (WiFi.status() != WL_CONNECTED) {
	delay(500);
	Serial.print(".");
	}
	Serial.println();

	Serial.println("WiFi connected");
	Serial.println("IP address: "); Serial.println(WiFi.localIP());

	// Setup MQTT subscription for sub_topic feed.
	mqtt.subscribe(&foo_sub_topic);
	}

	void loop() {
	// Ensure the connection to the MQTT server is alive (this will make the first
	// connection and automatically reconnect when disconnected). See the MQTT_connect
	// function definition further below.
	MQTT_connect();

	// Publish a buffer so big, it will corrupt the members of the mqtt
	// instance. That includes the subscription member. Boom! :) :)
	Serial.print(F("\nSending foo_pub_topic val "));
	Serial.print("...");
	if (! foo_pub_topic.publish(tooMuchData)) {
	Serial.println(F("Failed"));
	} else {
	Serial.println(F("OK!"));
	}

	delay(3000);

	// Now try to look at packets we subscribed to and see it
	// hit a LoadProhibited exception.
	Adafruit_MQTT_Subscribe *subscription;
	while ((subscription = mqtt.readSubscription(5000))) {
	if (subscription == &foo_sub_topic) {
	Serial.print(F("Got: "));
	Serial.println((char *)foo_sub_topic.lastread);
	}
	}

	// Will likely never make it here if you have bug described in
	// https://github.com/adafruit/Adafruit_MQTT_Library/issues/122
	Serial.println(F("Bug must have been fixed. Nice!"));
	}

	// Function to connect and reconnect as necessary to the MQTT server.
	// Should be called in the loop function and it will take care if connecting.
	void MQTT_connect() {
	int8_t ret;

	// Stop if already connected.
	if (mqtt.connected()) {
	return;
	}

	Serial.print("Connecting to MQTT... ");

	uint8_t retries = 3;
	while ((ret = mqtt.connect()) != 0) { // connect will return 0 for connected
	Serial.println(mqtt.connectErrorString(ret));
	Serial.println("Retrying MQTT connection in 5 seconds...");
	mqtt.disconnect();
	delay(5000); // wait 5 seconds
	retries--;
	if (retries == 0) {
	// basically die and wait for WDT to reset me
	while (1);
	}
	}
	Serial.println("MQTT Connected!");
	}