zyn-fusion PKGBUILD

PKGBUILD

# Maintainer: spider-mario <spidermario@free.fr>
pkgname=zyn-fusion
pkgver=3.0.3 # Note right now this uses latest from git...
_libuv=1.9.1
pkgrel=1
pkgdesc="ZynAddSubFX with a new interactive UI"
arch=('x86_64')
url="http://zynaddsubfx.sourceforge.net/zyn-fusion.html"
license=('custom')
depends=('fftw' 'libglvnd' 'mxml' 'jack2' 'liblo')
provides=('zynaddsubfx')
conflicts=('zynaddsubfx')
options=('!strip')
source=("http://dist.libuv.org/dist/v$_libuv/libuv-v$_libuv.tar.gz"
        "git+https://github.com/mruby-zest/mruby-zest-build"
        "git+https://github.com/zynaddsubfx/zynaddsubfx")
md5sums=("654bf6783ac7fc10435c84ec86720a6e" "SKIP" "SKIP")

prepare() {
    # Not sure how this ought to be done
    cd "$srcdir/zynaddsubfx"
    git submodule update --init
    cd "$srcdir/mruby-zest-build"
    git submodule update --init
}

build() {
    # ZynAddSubFX
    mkdir -p "$srcdir/zynaddsubfx/build"
    cd "$srcdir/zynaddsubfx/build"
    cmake .. -DGuiModule=zest -DDemoMode=release -DCMAKE_INSTALL_PREFIX=/usr
    make

    # Zyn-Fusion
    cd "$srcdir/mruby-zest-build"
    cp -ra "../libuv-v$_libuv/" deps/
    make builddep
    make
    make pack
}

package() {
    cd "$srcdir/zynaddsubfx/build"
    make install DESTDIR="$pkgdir/"

    cd "$srcdir/mruby-zest-build"
    install -d "$pkgdir"/opt/"$pkgname"

    # See: https://github.com/zynaddsubfx/zyn-fusion-build/blob/master/build-linux.rb
    ln -s /usr/lib/lv2/ZynAddSubFX.lv2presets "$pkgdir/opt/zyn-fusion/"
    ln -s ./zynaddsubfx/instruments/banks     "$pkgdir/opt/zyn-fusion/"
    cp -a  package/libzest.so                 "$pkgdir/opt/zyn-fusion/"
    cp -a  package/zest                       "$pkgdir/opt/zyn-fusion/zyn-fusion"
    cp -ra package/font                       "$pkgdir/opt/zyn-fusion/"
    cp -ra package/schema                     "$pkgdir/opt/zyn-fusion/"
    install -d "$pkgdir/opt/zyn-fusion/qml"
    touch "$pkgdir/opt/zyn-fusion/qml/MainWindow.qml"
    install -d "$pkgdir/opt/zyn-fusion/ZynAddSubFX.lv2"
    cp -ra ../zynaddsubfx/build/src/Plugin/ZynAddSubFX/lv2/* "$pkgdir/opt/zyn-fusion/ZynAddSubFX.lv2/"
    cp -ra ../zynaddsubfx/build/src/Plugin/ZynAddSubFX/vst/ZynAddSubFX.so "$pkgdir/opt/zyn-fusion/"
    ln -s /usr/bin/zynaddsubfx "$pkgdir/opt/zyn-fusion/"
    cp -a ../zynaddsubfx/COPYING "$pkgdir/opt/zyn-fusion/COPYING.zynaddsubfx"

    install -d "$pkgdir"/usr/bin
    ln -s /opt/"$pkgname"/zyn-fusion "$pkgdir"/usr/bin/

    install -d "$pkgdir"/usr/share/licenses/"$pkgname"
    cp -a LICENSE "$pkgdir"/usr/share/licenses/"$pkgname"/
}