builder pattern for lead

LeadBuilder.cls

@IsTest(seeAllData=false)
public with sharing class LeadBuilder {
  private Lead testLead =
    new Lead(
      FirstName     = 'test-FirstName',
      LastName      = 'test-LastName',
      Email         = 'test@email.com',
      Phone         = '01234 567 890',
      Street__c     = 'test street',
      City__c       = 'test city',
      Company       = 'test company',
      Lead_Type__c  = 'test lead type',
      Status        = 'New'
    );

  public LeadBuilder withRecordType(String recordTypeLabel) {
    this.testLead.RecordTypeId =
      Schema.SObjectType.Lead
        .getRecordTypeInfosByName()
        .get(recordTypeLabel)
        .getRecordTypeId();
    return this;
  }

  public LeadBuilder withFirstName(String firstName) {
    this.testLead.FirstName = firstName;
    return this;
  }

  public LeadBuilder withLastName(String lastName) {
    this.testLead.LastName = lastName;
    return this;
  }

  public LeadBuilder withEmail(String email) {
    this.testLead.Email = email;
    return this;
  }

  public LeadBuilder withLeadType(String leadType) {
    this.testLead.Lead_Type__c = leadType;
    return this;
  }

  public LeadBuilder withStatus(String status) {
    this.testLead.Status = status;
    return this;
  }

  public Lead build() {
    insert this.testLead;
    return this.testLead;
  }

  @IsTest
  private static void LeadBuilder_insertLead_Success() {
    Test.startTest();
      Lead testLead = new LeadBuilder()
                        .withFirstName('test-FirstName')
                        .withLastName('test-LastName')
                        .withEmail('test@email.com')
                        .withLeadType('testLeadType')
                        .withStatus('New')
                        .build();
    Test.stopTest();

    System.assertNotEquals(null,
                           testLead.Id);
  }
}

Now to create a simple lead I can do the minimum:

Lead simpleLead = new LeadBuilder().build();

or to set the Status to Qualified for a workflow scenario:

Lead qualifiedLead = new LeadBuilder().withStatus('Qualified').build();

and to set a specific recordtype:

Lead specificRecordTypeLead = new LeadBuilder().withRecordType('recordTypeLabel').build();

and I can stack those methods on top of each other to create a qualified lead with specific record type:

Lead specificRecordTypeLead = new LeadBuilder().withRecordType('recordTypeLabel').withStatus('Qualified').build();