so far, only used in a web app when I want to update a subset of available fields. eg when changing a password

example-usage-after.clj

(defentity user
  (has-many post)
  (has-many comment)

  ;; todo move user param transform function here
  (prepare
   (fn [attributes]
     (-> (transform-when-key-exists
          attributes
          {:password #(creds/hash-bcrypt %)
           :receive_comment_notifications #(= % "on")
           :receive_newsletter #(= % "on")})
         (assoc :roles (str [:user])))))
  
  (transform #(deserialize % :roles)))

example-usage-before.clj

(defentity user
  (has-many post)
  (has-many comment)

  ;; todo move user param transform function here
  (prepare
   (fn [attributes]
     (-> (if (:password attributes)
           (assoc attributes :password (creds/hash-bcrypt (:password attributes)))
            attributes)
         (assoc :roles (str [:user])))))
  
  (transform #(deserialize % :roles)))

transform-when-key-exists-test.clj

(deftest transform-when-key-exists-test
  (testing "Returns a map with all transformations applied"
    (is (= (transform-when-key-exists
            {:a 1 :b 2}
            {:a #(inc %)
             :c #(inc %)})
           {:a 2 :b 2}))))

transform-when-key-exists.clj

(defn transform-when-key-exists
  "(transform-when-key-exists
 {:a 1
  :b 2}
 {:a #(inc %)
  :c #(inc %)})
=> {:a 2 :b 2}"
  [source transformations]
  (reduce
   (fn [m x]
     (merge m
            (let [[key value] x]
              (if-let [transform (get transformations key)]
                {key (transform value)}
                x))))
   {}
   source))