Groovy compiler customization with type checking and static compilation

MyExtension.groovy

beforeVisitMethod { methodNode ->
	println "calling ${methodNode.name}(${methodNode.parameters.join(',')})"
}

afterMethodCall { call ->
	if (getTargetMethod(call).name=='plus') {
        addStaticTypeError('plus() not allowed',call)
        handled = true
    }

    if (getTargetMethod(call).name=='somar') {
    	if (getTargetMethod(call).returnType.typeClass != int) {	
        	addStaticTypeError('somar() must returns int', call)
        	handled = true
    	}

    	if (getTargetMethod(call).parameters*.type*.typeClass != [int, int]) {	
        	addStaticTypeError('somar() must be int, int parameters', call)
        	handled = true
    	}
    }
}

MyTypedScript.groovy

int somar(int a, int b) {
	a + b
}

println "Resultado: ${somar(2, 2)}"

rules.groovy

import groovy.transform.CompileStatic
 
withConfig(configuration) {
	ast(extensions: ['MyExtension.groovy'], CompileStatic)

	inline(phase:'CONVERSION') { source, context, classNode ->
        println ">> CONVERSION $classNode"
    }

	imports {
		star 'java.time'
		normal 'java.util.function.Function', 'java.util.function.Supplier'
	}

	secureAst {
       closuresAllowed = false
       methodDefinitionAllowed = true
   }
}

run.sh

groovy --configscript rules.groovy MyTypedScript